libraries: switch to dht11.h from keyestudio

a93d1575a96c77b5cc9184bf3ceca3ecf9d61779  /home/vbatts/KS0530 Keyestudio Solar Tracking Kit.zip
fea14b18807e3dac4b112354eefb76a5e0f76c4b  /home/vbatts/KS0530 Keyestudio Solar Tracking Kit/Libraries/Dht11.zip

Dht11/dht11.cpp

@@ -0,0 +1,101 @@
+//
+//    FILE: dht11.cpp
+// VERSION: 0.4.1
+// PURPOSE: DHT11 Temperature & Humidity Sensor library for Arduino
+// LICENSE: GPL v3 (http://www.gnu.org/licenses/gpl.html)
+//
+// DATASHEET: http://www.micro4you.com/files/sensor/DHT11.pdf
+//
+// HISTORY:
+// George Hadjikyriacou - Original version (??)
+// Mod by SimKard - Version 0.2 (24/11/2010)
+// Mod by Rob Tillaart - Version 0.3 (28/03/2011)
+// + added comments
+// + removed all non DHT11 specific code
+// + added references
+// Mod by Rob Tillaart - Version 0.4 (17/03/2012)
+// + added 1.0 support
+// Mod by Rob Tillaart - Version 0.4.1 (19/05/2012)
+// + added error codes
+//
+
+#include "dht11.h"
+
+// Return values:
+// DHTLIB_OK
+// DHTLIB_ERROR_CHECKSUM
+// DHTLIB_ERROR_TIMEOUT
+int dht11::read(int pin)
+{
+    // BUFFER TO RECEIVE
+    uint8_t bits[5]={0,0,0,0,0};
+    uint8_t cnt = 7;
+    uint8_t idx = 0;
+
+    // EMPTY BUFFER
+    for (int i=0; i< 5; i++) bits[i] = 0;
+
+    // REQUEST SAMPLE
+    pinMode(pin, OUTPUT);
+    digitalWrite(pin, LOW);
+    delay(20);
+    digitalWrite(pin, HIGH);
+    delayMicroseconds(40);
+    pinMode(pin, INPUT);
+
+    // ACKNOWLEDGE or TIMEOUT
+    unsigned int loopCnt = 80;
+    while(digitalRead(pin) == LOW)
+    {
+        delayMicroseconds(1);
+        if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;
+    }
+
+    loopCnt = 80;
+    while(digitalRead(pin) == HIGH)
+    {
+        delayMicroseconds(1);
+        if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;
+    }
+
+    // READ OUTPUT - 40 BITS => 5 BYTES or TIMEOUT
+    for (int i=0; i<40; i++)
+    {
+        loopCnt = 10000;
+        while(digitalRead(pin) == LOW)
+            if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;
+
+        unsigned long t = micros();
+
+        loopCnt = 10000;
+        while(digitalRead(pin) == HIGH)
+            if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;
+
+        if ((micros() - t) > 40) bits[idx] |= (1 << cnt);
+        if (cnt == 0)   // next byte?
+        {
+            cnt = 7;    // restart at MSB
+            idx++;      // next byte!
+        }
+        else cnt--;
+    }
+
+    // WRITE TO RIGHT VARS
+        // as bits[1] and bits[3] are allways zero they are omitted in formulas.
+    humidity    = bits[0];
+    temperature = bits[2];
+
+    byt0=bits[0];
+    byt1=bits[1];
+    byt2=bits[2];
+    byt3=bits[3];
+    byt4=bits[4];
+
+    uint8_t sum = bits[0] + bits[1]+bits[2]+bits[3];
+
+    if (bits[4] != sum) return DHTLIB_ERROR_CHECKSUM;
+    return DHTLIB_OK;
+}
+//
+// END OF FILE
+//

Dht11/dht11.h

@@ -0,0 +1,33 @@
+
+
+#ifndef dht11_h
+#define dht11_h
+
+#if defined(ARDUINO) && (ARDUINO >= 100)
+#include <Arduino.h>
+#else
+#include <WProgram.h>
+#endif
+
+#define DHT11LIB_VERSION "0.4.1"
+
+#define DHTLIB_OK               0
+#define DHTLIB_ERROR_CHECKSUM   -1
+#define DHTLIB_ERROR_TIMEOUT    -2
+
+class dht11
+{
+public:
+    int read(int pin);
+    int humidity;
+    int temperature;
+    int byt0;
+    int byt1;
+    int byt2;
+    int byt3;
+    int byt4;
+};
+#endif
+//
+// END OF FILE
+//

Dht11/examples/dht11/dht11.ino

@@ -0,0 +1,94 @@
+double Fahrenheit(double celsius) 
+{
+        return 1.8 * celsius + 32;
+}    //摄氏温度度转化为华氏温度
+
+double Kelvin(double celsius)
+{
+        return celsius + 273.15;
+}     //摄氏温度转化为开氏温度
+
+// 露点（点在此温度时，空气饱和并产生露珠）
+// 参考: http://wahiduddin.net/calc/density_algorithms.htm 
+double dewPoint(double celsius, double humidity)
+{
+        double A0= 373.15/(273.15 + celsius);
+        double SUM = -7.90298 * (A0-1);
+        SUM += 5.02808 * log10(A0);
+        SUM += -1.3816e-7 * (pow(10, (11.344*(1-1/A0)))-1) ;
+        SUM += 8.1328e-3 * (pow(10,(-3.49149*(A0-1)))-1) ;
+        SUM += log10(1013.246);
+        double VP = pow(10, SUM-3) * humidity;
+        double T = log(VP/0.61078);   // temp var
+        return (241.88 * T) / (17.558-T);
+}
+
+// 快速计算露点，速度是5倍dewPoint()
+// 参考: http://en.wikipedia.org/wiki/Dew_point
+double dewPointFast(double celsius, double humidity)
+{
+        double a = 17.271;
+        double b = 237.7;
+        double temp = (a * celsius) / (b + celsius) + log(humidity/100);
+        double Td = (b * temp) / (a - temp);
+        return Td;
+}
+
+#include <dht11.h>
+
+dht11 DHT11;
+
+#define DHT11PIN 2
+
+void setup()
+{
+  Serial.begin(9600);
+  Serial.println("DHT11 TEST PROGRAM ");
+  Serial.print("LIBRARY VERSION: ");
+  Serial.println(DHT11LIB_VERSION);
+  Serial.println();
+}
+
+void loop()
+{
+  Serial.println("\n");
+
+  int chk = DHT11.read(DHT11PIN);
+
+  Serial.print("Read sensor: ");
+  switch (chk)
+  {
+    case DHTLIB_OK: 
+                Serial.println("OK"); 
+                break;
+    case DHTLIB_ERROR_CHECKSUM: 
+                Serial.println("Checksum error"); 
+                break;
+    case DHTLIB_ERROR_TIMEOUT: 
+                Serial.println("Time out error"); 
+                break;
+    default: 
+                Serial.println("Unknown error"); 
+                break;
+  }
+
+  Serial.print("Humidity (%): ");
+  Serial.println((float)DHT11.humidity, 2);
+
+  Serial.print("Temperature (oC): ");
+  Serial.println((float)DHT11.temperature, 2);
+
+  Serial.print("Temperature (oF): ");
+  Serial.println(Fahrenheit(DHT11.temperature), 2);
+
+  Serial.print("Temperature (K): ");
+  Serial.println(Kelvin(DHT11.temperature), 2);
+
+  Serial.print("Dew Point (oC): ");
+  Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));
+
+  Serial.print("Dew PointFast (oC): ");
+  Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));
+
+  delay(2000);
+}