mirror of
https://github.com/jart/cosmopolitan.git
synced 2025-02-07 23:13:34 +00:00
23b72eb617
This change fixes minor bugs and adds a feature, which lets us store the ELF symbol table, inside the ZIP directory. We use the path /zip/.symtab which can be safely removed using a zip editing tool, to make the binary smaller after compilation. This supplements the existing method of using a separate .com.dbg file, which is still supported. The intent is people don't always know that it's a good idea to download the debug file. It's not great having someone's first experience be a crash report, that only has numbers rather than symbols. This will help fix that!
100 lines
3.2 KiB
ArmAsm
100 lines
3.2 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│vi: set et ft=asm ts=8 tw=8 fenc=utf-8 :vi│
|
|
╞══════════════════════════════════════════════════════════════════════════════╡
|
|
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
|
│ │
|
|
│ Permission to use, copy, modify, and/or distribute this software for │
|
|
│ any purpose with or without fee is hereby granted, provided that the │
|
|
│ above copyright notice and this permission notice appear in all copies. │
|
|
│ │
|
|
│ THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL │
|
|
│ WARRANTIES WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED │
|
|
│ WARRANTIES OF MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE │
|
|
│ AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL │
|
|
│ DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR │
|
|
│ PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER │
|
|
│ TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR │
|
|
│ PERFORMANCE OF THIS SOFTWARE. │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#include "libc/dce.h"
|
|
#include "libc/macros.internal.h"
|
|
#include "libc/notice.inc"
|
|
#include "libc/sysv/consts/prot.h"
|
|
#include "libc/sysv/consts/map.h"
|
|
#include "libc/calls/strace.internal.h"
|
|
#include "libc/dce.h"
|
|
.text.startup
|
|
|
|
// Cosmopolitan runtime.
|
|
//
|
|
// @param edi is argc
|
|
// @param rsi is argv
|
|
// @param rdx is environ
|
|
// @param rcx is auxv
|
|
// @noreturn
|
|
cosmo: push %rbp
|
|
mov %rsp,%rbp
|
|
mov %edi,%r12d
|
|
mov %rsi,%r13
|
|
mov %rdx,%r14
|
|
mov %rcx,%r15
|
|
#ifdef SYSDEBUG
|
|
call __strace_init
|
|
mov %eax,%r12d
|
|
#endif /* SYSDEBUG */
|
|
#ifdef __FAST_MATH__
|
|
push %rax
|
|
stmxcsr (%rsp)
|
|
orl $0x8040,(%rsp)
|
|
ldmxcsr (%rsp)
|
|
pop %rax
|
|
#endif
|
|
call _init
|
|
ezlea __init_array_start,ax # static ctors in forward order
|
|
.weak __init_array_start # could be called multiple times
|
|
ezlea __init_array_end,cx # idempotency recommended
|
|
.weak __init_array_end # @see ape/ape.lds
|
|
1: cmp %rax,%rcx
|
|
je 2f
|
|
push %rax
|
|
push %rcx
|
|
call .Largs
|
|
call *(%rax)
|
|
pop %rcx
|
|
pop %rax
|
|
add $8,%rax
|
|
jmp 1b
|
|
2: call .Largs
|
|
.weak main
|
|
call main
|
|
xchg %eax,%edi
|
|
call exit
|
|
.Largs: mov %r12d,%edi
|
|
mov %r13,%rsi
|
|
mov %r14,%rdx
|
|
mov %r15,%rcx
|
|
ret
|
|
.endfn cosmo,weak
|
|
|
|
#ifdef __PG__
|
|
.init.start 306,_init_ftrace
|
|
push %rdi
|
|
push %rsi
|
|
call ftrace_init
|
|
mov %eax,%r12d
|
|
pop %rsi
|
|
pop %rdi
|
|
.init.end 306,_init_ftrace
|
|
#endif
|
|
|
|
#if IsModeDbg()
|
|
#ifdef SYSDEBUG
|
|
.init.start 307,_init_printargs
|
|
push %rdi
|
|
push %rsi
|
|
call __printargs
|
|
pop %rsi
|
|
pop %rdi
|
|
.init.end 307,_init_printargs
|
|
#endif
|
|
#endif
|