mirror of
https://github.com/jart/cosmopolitan.git
synced 2025-02-12 09:17:53 +00:00
f4f4caab0e
I wanted a tiny scriptable meltdown proof way to run userspace programs and visualize how program execution impacts memory. It helps to explain how things like Actually Portable Executable works. It can show you how the GCC generated code is going about manipulating matrices and more. I didn't feel fully comfortable with Qemu and Bochs because I'm not smart enough to understand them. I wanted something like gVisor but with much stronger levels of assurances. I wanted a single binary that'll run, on all major operating systems with an embedded GPL barrier ZIP filesystem that is tiny enough to transpile to JavaScript and run in browsers too. https://justine.storage.googleapis.com/emulator625.mp4
63 lines
2.9 KiB
ArmAsm
63 lines
2.9 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│vi: set et ft=asm ts=8 tw=8 fenc=utf-8 :vi│
|
|
╞══════════════════════════════════════════════════════════════════════════════╡
|
|
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
|
│ │
|
|
│ This program is free software; you can redistribute it and/or modify │
|
|
│ it under the terms of the GNU General Public License as published by │
|
|
│ the Free Software Foundation; version 2 of the License. │
|
|
│ │
|
|
│ This program is distributed in the hope that it will be useful, but │
|
|
│ WITHOUT ANY WARRANTY; without even the implied warranty of │
|
|
│ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU │
|
|
│ General Public License for more details. │
|
|
│ │
|
|
│ You should have received a copy of the GNU General Public License │
|
|
│ along with this program; if not, write to the Free Software │
|
|
│ Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA │
|
|
│ 02110-1301 USA │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#include "libc/macros.h"
|
|
.text.windows
|
|
|
|
/ Epilogues for calling functions w/ Microsoft x64 convention.
|
|
/
|
|
/ @param %rax is address of windows x64 function to call
|
|
/ @param %rsi is ignored
|
|
/ @param %rdx,%rcx,%r8,%r9,stack are params (unlimited)
|
|
/ @param %xmm0,%xmm1,%xmm2 are double params (limited to 3)
|
|
/ @return is in %rax, %xmm0, or %st
|
|
/ @note GCC 4.8+ and Clang can avoid this indirection
|
|
/ @note thunk that jumps here must setup frame
|
|
/ @note this is so much faster than nt2sysv()
|
|
__sysv2nt14:
|
|
pushq 72(%rbp)
|
|
pushq 64(%rbp)
|
|
__sysv2nt12:
|
|
pushq 56(%rbp)
|
|
pushq 48(%rbp)
|
|
__sysv2nt10:
|
|
pushq 40(%rbp)
|
|
pushq 32(%rbp)
|
|
__sysv2nt8:
|
|
pushq 24(%rbp)
|
|
pushq 16(%rbp)
|
|
__sysv2nt6:
|
|
push %r9
|
|
push %r8
|
|
__sysv2nt:
|
|
mov %rdx,%r8
|
|
mov %rcx,%r9
|
|
mov %rdi,%rcx
|
|
mov %rsi,%rdx
|
|
sub $32,%rsp
|
|
call *%rax
|
|
leave
|
|
ret
|
|
.endfn __sysv2nt,globl,hidden
|
|
.endfn __sysv2nt6,globl,hidden
|
|
.endfn __sysv2nt8,globl,hidden
|
|
.endfn __sysv2nt10,globl,hidden
|
|
.endfn __sysv2nt12,globl,hidden
|
|
.endfn __sysv2nt14,globl,hidden
|
|
.source __FILE__
|