mirror of
https://github.com/jart/cosmopolitan.git
synced 2025-02-14 10:18:02 +00:00
957c61cbbf
This change upgrades to GCC 12.3 and GNU binutils 2.42. The GNU linker appears to have changed things so that only a single de-duplicated str table is present in the binary, and it gets placed wherever the linker wants, regardless of what the linker script says. To cope with that we need to stop using .ident to embed licenses. As such, this change does significant work to revamp how third party licenses are defined in the codebase, using `.section .notice,"aR",@progbits`. This new GCC 12.3 toolchain has support for GNU indirect functions. It lets us support __target_clones__ for the first time. This is used for optimizing the performance of libc string functions such as strlen and friends so far on x86, by ensuring AVX systems favor a second codepath that uses VEX encoding. It shaves some latency off certain operations. It's a useful feature to have for scientific computing for the reasons explained by the test/libcxx/openmp_test.cc example which compiles for fifteen different microarchitectures. Thanks to the upgrades, it's now also possible to use newer instruction sets, such as AVX512FP16, VNNI. Cosmo now uses the %gs register on x86 by default for TLS. Doing it is helpful for any program that links `cosmo_dlopen()`. Such programs had to recompile their binaries at startup to change the TLS instructions. That's not great, since it means every page in the executable needs to be faulted. The work of rewriting TLS-related x86 opcodes, is moved to fixupobj.com instead. This is great news for MacOS x86 users, since we previously needed to morph the binary every time for that platform but now that's no longer necessary. The only platforms where we need fixup of TLS x86 opcodes at runtime are now Windows, OpenBSD, and NetBSD. On Windows we morph TLS to point deeper into the TIB, based on a TlsAlloc assignment, and on OpenBSD/NetBSD we morph %gs back into %fs since the kernels do not allow us to specify a value for the %gs register. OpenBSD users are now required to use APE Loader to run Cosmo binaries and assimilation is no longer possible. OpenBSD kernel needs to change to allow programs to specify a value for the %gs register, or it needs to stop marking executable pages loaded by the kernel as mimmutable(). This release fixes __constructor__, .ctor, .init_array, and lastly the .preinit_array so they behave the exact same way as glibc. We no longer use hex constants to define math.h symbols like M_PI.
145 lines
4.7 KiB
ArmAsm
145 lines
4.7 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│ vi: set noet ft=asm ts=8 sw=8 fenc=utf-8 :vi │
|
|
╞══════════════════════════════════════════════════════════════════════════════╡
|
|
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
|
│ │
|
|
│ Permission to use, copy, modify, and/or distribute this software for │
|
|
│ any purpose with or without fee is hereby granted, provided that the │
|
|
│ above copyright notice and this permission notice appear in all copies. │
|
|
│ │
|
|
│ THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL │
|
|
│ WARRANTIES WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED │
|
|
│ WARRANTIES OF MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE │
|
|
│ AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL │
|
|
│ DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR │
|
|
│ PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER │
|
|
│ TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR │
|
|
│ PERFORMANCE OF THIS SOFTWARE. │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#include "libc/macros.internal.h"
|
|
#include "libc/sysv/consts/prot.h"
|
|
#include "libc/sysv/consts/map.h"
|
|
#include "libc/intrin/strace.internal.h"
|
|
#include "libc/sysv/consts/map.h"
|
|
#include "libc/dce.h"
|
|
#ifdef __x86_64__
|
|
.text.startup
|
|
|
|
// Cosmopolitan runtime.
|
|
//
|
|
// @param edi is argc
|
|
// @param rsi is argv
|
|
// @param rdx is environ
|
|
// @param rcx is auxv
|
|
// @noreturn
|
|
cosmo: push %rbp
|
|
mov %rsp,%rbp
|
|
mov %edi,%r12d
|
|
mov %rsi,%r13
|
|
mov %rdx,%r14
|
|
mov %rcx,%r15
|
|
|
|
#if SYSDEBUG
|
|
call __strace_init
|
|
mov %eax,%r12d
|
|
#endif /* SYSDEBUG */
|
|
|
|
#ifndef NOX87
|
|
// Windows always initializes FPU to douuble precision.
|
|
// WSL breaks Linux ABI by initializing FPU to double precision.
|
|
// This code makes long double long again.
|
|
//
|
|
// @see System V Application Binary Interface NexGen32e Architecture
|
|
// Processor Supplement, Version 1.0, December 5th, 2018
|
|
// Section 3.4.1: Initial Stack and Register State
|
|
fldcw 1f(%rip)
|
|
.rodata
|
|
.balign 2
|
|
// 8087 FPU Control Word
|
|
// IM: Invalid Operation ───────────────┐
|
|
// DM: Denormal Operand ───────────────┐│
|
|
// ZM: Zero Divide ───────────────────┐││
|
|
// OM: Overflow ─────────────────────┐│││
|
|
// UM: Underflow ───────────────────┐││││
|
|
// PM: Precision ──────────────────┐│││││
|
|
// PC: Precision Control ───────┐ ││││││
|
|
// {float,∅,double,long double}│ ││││││
|
|
// RC: Rounding Control ──────┐ │ ││││││
|
|
// {even, →-∞, →+∞, →0} │┌┤ ││││││
|
|
// ┌┤││ ││││││
|
|
// d││││rr││││││
|
|
1: .short 0b00000000000000000001101111111
|
|
.previous
|
|
#endif
|
|
|
|
#ifdef __FAST_MATH__
|
|
push %rax
|
|
stmxcsr (%rsp)
|
|
orl $0x8040,(%rsp)
|
|
ldmxcsr (%rsp)
|
|
pop %rax
|
|
#endif
|
|
|
|
// run assembly init
|
|
call _init
|
|
|
|
// call constructors
|
|
.weak __init_array_end
|
|
.weak __init_array_start
|
|
mov $__init_array_start,%eax
|
|
1: cmp $__init_array_end,%eax
|
|
je 2f
|
|
push %rax
|
|
push %rax
|
|
call .Largs
|
|
call *(%rax)
|
|
pop %rax
|
|
pop %rax
|
|
add $8,%eax
|
|
jmp 1b
|
|
|
|
// call main()
|
|
2: call .Largs
|
|
.weak main
|
|
call main
|
|
xchg %eax,%edi
|
|
call exit
|
|
|
|
.Largs: mov %r12d,%edi
|
|
mov %r13,%rsi
|
|
mov %r14,%rdx
|
|
mov %r15,%rcx
|
|
ret
|
|
.endfn cosmo,weak
|
|
|
|
// Enables Thread Local Storage.
|
|
.init.start 304,_init_tls
|
|
push %rdi
|
|
push %rsi
|
|
call __enable_tls
|
|
pop %rsi
|
|
pop %rdi
|
|
.init.end 304,_init_tls
|
|
|
|
#if IsAsan()
|
|
.init.start 305,_init_symbols
|
|
push %rdi
|
|
push %rsi
|
|
call __init_symbols
|
|
pop %rsi
|
|
pop %rdi
|
|
.init.end 305,_init_symbols
|
|
#endif
|
|
|
|
#ifdef FTRACE
|
|
.init.start 306,_init_ftrace
|
|
push %rdi
|
|
push %rsi
|
|
call ftrace_init
|
|
mov %eax,%r12d
|
|
pop %rsi
|
|
pop %rdi
|
|
.init.end 306,_init_ftrace
|
|
#endif
|
|
|
|
#endif /* __x86_64__ */
|