mirror of
https://github.com/jart/cosmopolitan.git
synced 2025-02-01 03:53:33 +00:00
98909b1391
- Update a couple unicode data files - Disable strace during logger calls - SQLite now uses pread() / pwrite() - pread() past EOF on NT now returns 0 - Make the NT mmap() and fork() code elegant - Give NT a big performance boost with memory - Add many more mmap() tests to prove it works
102 lines
3.6 KiB
ArmAsm
102 lines
3.6 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│vi: set et ft=asm ts=8 tw=8 fenc=utf-8 :vi│
|
|
╞══════════════════════════════════════════════════════════════════════════════╡
|
|
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
|
│ │
|
|
│ Permission to use, copy, modify, and/or distribute this software for │
|
|
│ any purpose with or without fee is hereby granted, provided that the │
|
|
│ above copyright notice and this permission notice appear in all copies. │
|
|
│ │
|
|
│ THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL │
|
|
│ WARRANTIES WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED │
|
|
│ WARRANTIES OF MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE │
|
|
│ AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL │
|
|
│ DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR │
|
|
│ PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER │
|
|
│ TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR │
|
|
│ PERFORMANCE OF THIS SOFTWARE. │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#include "libc/dce.h"
|
|
#include "libc/macros.internal.h"
|
|
#include "libc/notice.inc"
|
|
#include "libc/runtime/internal.h"
|
|
.section .start,"ax",@progbits
|
|
|
|
// System Five userspace program entrypoint.
|
|
//
|
|
// @param rsp is [n,argv₀..argvₙ₋₁,0,envp₀..,0,auxv₀..,0,..]
|
|
// @note FreeBSD is special (see freebsd/lib/csu/amd64/...)
|
|
// @noreturn
|
|
_start:
|
|
|
|
#if SupportsFreebsd()
|
|
// detect free besiyata dishmaya
|
|
test %rdi,%rdi
|
|
cmovnz %rdi,%rsp
|
|
jz 0f
|
|
movb $FREEBSD,__hostos(%rip)
|
|
#endif
|
|
|
|
// get startup timestamp as early as possible
|
|
// its used by --strace flag and kprintf() %T
|
|
0: rdtsc
|
|
ezlea kStartTsc,bx
|
|
mov %eax,(%rbx)
|
|
mov %edx,4(%rbx)
|
|
|
|
// translates arguments from old stack abi
|
|
mov (%rsp),%ebx # argc
|
|
lea 8(%rsp),%rsi # argv
|
|
lea 16(%rsp,%rbx,8),%rdx # envp
|
|
mov %rsp,__oldstack(%rip)
|
|
and $-16,%rsp
|
|
xor %ebp,%ebp
|
|
// bofram 9f
|
|
|
|
// make win32 imps noop
|
|
.weak ape_idata_iat
|
|
.weak ape_idata_iatend
|
|
ezlea missingno,ax
|
|
ezlea ape_idata_iat,di
|
|
ezlea ape_idata_iatend,cx
|
|
sub %rdi,%rcx
|
|
shr $3,%ecx
|
|
rep stosq
|
|
|
|
// scan through environment varis
|
|
// find start of auxiliary values
|
|
xor %eax,%eax
|
|
or $-1,%ecx
|
|
mov %rdx,%rdi
|
|
repnz scasq
|
|
mov %rdi,%rcx # auxv
|
|
|
|
#if SupportsXnu()
|
|
// should probably be removed in favor of newer apis
|
|
testb IsXnu()
|
|
jz 1f # polyfill xnu auxv
|
|
push $0 # auxv[1][1]=0
|
|
push $0 # auxv[1][0]=0
|
|
mov (%rcx),%rax # executable_path=BIN
|
|
lea 16(%rax),%rax # BIN
|
|
push %rax # auxv[0][0]=BIN
|
|
push $31 # auxv[0][0]=AT_EXECFN
|
|
mov %rsp,%rcx # auxv
|
|
#endif
|
|
|
|
// enter cosmopolitan runtime
|
|
1: mov %ebx,%edi
|
|
call cosmo
|
|
9: .unreachable
|
|
.endfn _start,weak,hidden
|
|
|
|
#if SupportsXnu()
|
|
// Macintosh userspace program entrypoint.
|
|
//
|
|
// @param rsp is [n,argv₀..argvₙ₋₁,0,envp₀..,0,auxv₀..,0,..]
|
|
// @note FreeBSD is special (see freebsd/lib/csu/amd64/...)
|
|
// @noreturn
|
|
_xnu: movb $XNU,__hostos(%rip)
|
|
jmp 0b
|
|
.endfn _xnu,weak,hidden
|
|
#endif
|