mirror of
https://github.com/jart/cosmopolitan.git
synced 2025-01-31 19:43:32 +00:00
ea0b5d9d1c
A new rollup tool now exists for flattening out the headers in a way that works better for our purposes than cpp. A lot of the API clutter has been removed. APIs that aren't a sure thing in terms of general recommendation are now marked internal. There's now a smoke test for the amalgamation archive and gigantic header file. So we can now guarantee you can use this project on the easiest difficulty setting without the gigantic repository. A website is being created, which is currently a work in progress: https://justine.storage.googleapis.com/cosmopolitan/index.html
82 lines
3.3 KiB
ArmAsm
82 lines
3.3 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
||
│vi: set et ft=asm ts=8 tw=8 fenc=utf-8 :vi│
|
||
╞══════════════════════════════════════════════════════════════════════════════╡
|
||
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
||
│ │
|
||
│ This program is free software; you can redistribute it and/or modify │
|
||
│ it under the terms of the GNU General Public License as published by │
|
||
│ the Free Software Foundation; version 2 of the License. │
|
||
│ │
|
||
│ This program is distributed in the hope that it will be useful, but │
|
||
│ WITHOUT ANY WARRANTY; without even the implied warranty of │
|
||
│ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU │
|
||
│ General Public License for more details. │
|
||
│ │
|
||
│ You should have received a copy of the GNU General Public License │
|
||
│ along with this program; if not, write to the Free Software │
|
||
│ Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA │
|
||
│ 02110-1301 USA │
|
||
╚─────────────────────────────────────────────────────────────────────────────*/
|
||
#include "libc/macros.h"
|
||
#include "libc/dce.h"
|
||
#include "libc/notice.inc"
|
||
#define INITIAL_CAPACITY 4
|
||
|
||
/ Invokes deferred function calls.
|
||
/
|
||
/ This offers behavior similar to std::unique_ptr. Functions
|
||
/ overwrite their return addresses jumping here, and pushing
|
||
/ exactly one entry on the shadow stack below. Functions may
|
||
/ repeat that process multiple times, in which case the body
|
||
/ of this gadget loops and unwinds as a natural consequence.
|
||
/
|
||
/ @param rax,rdx,xmm0,xmm1,st0,st1 is return value
|
||
/ @see test/libc/runtime/gc_test.c
|
||
/ <LIMBO>
|
||
__gc: decq __garbage(%rip)
|
||
mov __garbage(%rip),%r8
|
||
mov __garbage+16(%rip),%r9
|
||
js 9f
|
||
shl $5,%r8
|
||
lea (%r9,%r8),%r8
|
||
mov 8(%r8),%r9
|
||
mov 16(%r8),%rdi
|
||
push 24(%r8)
|
||
/ </LIMBO>
|
||
push %rbp
|
||
mov %rsp,%rbp
|
||
sub $0x20,%rsp
|
||
push %rax
|
||
push %rdx
|
||
movdqa %xmm0,-0x20(%rbp)
|
||
movdqa %xmm1,-0x10(%rbp)
|
||
call *%r9
|
||
movdqa -0x10(%rbp),%xmm1
|
||
movdqa -0x20(%rbp),%xmm0
|
||
pop %rdx
|
||
pop %rax
|
||
leave
|
||
ret
|
||
9: call abort
|
||
.endfn __gc,globl,hidden
|
||
.source __FILE__
|
||
|
||
.bss
|
||
.align 8
|
||
__garbage:
|
||
.quad 0 # garbage.i
|
||
.quad 0 # garbage.n
|
||
.quad 0 # garbage.p
|
||
.rept INITIAL_CAPACITY
|
||
.quad 0 # garbage.p[𝑖].frame
|
||
.quad 0 # garbage.p[𝑖].fn
|
||
.quad 0 # garbage.p[𝑖].arg
|
||
.quad 0 # garbage.p[𝑖].ret
|
||
.endr
|
||
.endobj __garbage,globl,hidden
|
||
.previous
|
||
|
||
.init.start 100,_init_garbage
|
||
movb $INITIAL_CAPACITY,__garbage+8(%rip)
|
||
movl $__garbage+24,__garbage+16(%rip)
|
||
.init.end 100,_init_garbage
|