mirror of
https://github.com/jart/cosmopolitan.git
synced 2025-02-01 03:53:33 +00:00
db0d8dd806
The "no modify self" variant of Actually Portable Executable is now
supported on all platforms. If you use `$(APE_NO_MODIFY_SELF)` then
ld.bfd will embed a 4096 byte ELF binary and a 4096 byte Macho file
which are installed on the fly to ${TMPDIR:-/tmp}, which enables us
launch the executable, without needing to copy the whole executable
To prevent it from copying a tiny executable to your temp directory
you need to install the `ape` command (renamed from ape-loader), to
a system path. For example:
# FreeBSD / NetBSD / OpenBSD
make -j8 o//ape/ape
cp o//ape/ape /usr/bin/ape
# Mac OS
# make -j8 o//ape/ape.macho
curl https://justine.lol/ape.macho >/usr/bin/ape
chmod +x /usr/bin/ape
On Linux you can get even more performance with the new binfmt_misc
support which makes launching non-modifying APE binaries as fast as
launching ELF executables. Running the following command:
# Linux
ape/apeinstall.sh
Will copy APE loader to /usr/bin/ape and register with binfmt_misc
Lastly, this change also fixes a really interesting race condition
with OpenBSD thread joining.
93 lines
3.4 KiB
ArmAsm
93 lines
3.4 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│vi: set et ft=asm ts=8 tw=8 fenc=utf-8 :vi│
|
|
╞══════════════════════════════════════════════════════════════════════════════╡
|
|
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
|
│ │
|
|
│ Permission to use, copy, modify, and/or distribute this software for │
|
|
│ any purpose with or without fee is hereby granted, provided that the │
|
|
│ above copyright notice and this permission notice appear in all copies. │
|
|
│ │
|
|
│ THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL │
|
|
│ WARRANTIES WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED │
|
|
│ WARRANTIES OF MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE │
|
|
│ AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL │
|
|
│ DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR │
|
|
│ PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER │
|
|
│ TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR │
|
|
│ PERFORMANCE OF THIS SOFTWARE. │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#include "libc/dce.h"
|
|
#include "libc/macros.internal.h"
|
|
#include "libc/notice.inc"
|
|
#include "libc/runtime/internal.h"
|
|
.section .start,"ax",@progbits
|
|
|
|
// System Five userspace program entrypoint.
|
|
//
|
|
// @param rsp is [n,argv₀..argvₙ₋₁,0,envp₀..,0,auxv₀..,0,..]
|
|
// @note FreeBSD is special (see freebsd/lib/csu/amd64/...)
|
|
// @note NetBSD will only zero the call-clobbered registers
|
|
// @note ape.S and ape-loader both set RCX to XNU on Darwin
|
|
// @noreturn
|
|
_start:
|
|
|
|
#if SupportsFreebsd()
|
|
// detect free besiyata dishmaya
|
|
test %rdi,%rdi
|
|
cmovnz %rdi,%rsp
|
|
jz 0f
|
|
movb $FREEBSD,%cl
|
|
0:
|
|
#endif
|
|
|
|
// set operating system when already detected
|
|
mov %cl,__hostos(%rip)
|
|
|
|
// get startup timestamp as early as possible
|
|
// its used by --strace flag and kprintf() %T
|
|
rdtsc
|
|
ezlea kStartTsc,bx
|
|
mov %eax,(%rbx)
|
|
mov %edx,4(%rbx)
|
|
|
|
// translates arguments from old stack abi
|
|
mov (%rsp),%ebx # argc
|
|
lea 8(%rsp),%rsi # argv
|
|
lea 16(%rsp,%rbx,8),%rdx # envp
|
|
mov %rsp,__oldstack(%rip)
|
|
and $-16,%rsp
|
|
xor %ebp,%ebp
|
|
// bofram 9f
|
|
|
|
// make win32 imps noop
|
|
.weak ape_idata_iat
|
|
.weak ape_idata_iatend
|
|
ezlea missingno,ax
|
|
ezlea ape_idata_iat,di
|
|
ezlea ape_idata_iatend,cx
|
|
sub %rdi,%rcx
|
|
shr $3,%ecx
|
|
rep stosq
|
|
|
|
// scan through environment varis
|
|
// find start of auxiliary values
|
|
xor %eax,%eax
|
|
or $-1,%ecx
|
|
mov %rdx,%rdi
|
|
repnz scasq
|
|
mov %rdi,%rcx # auxv
|
|
|
|
#if SupportsXnu()
|
|
// xnu doesn't have auxiliary values
|
|
testb IsXnu()
|
|
jz 1f # polyfill xnu auxv
|
|
push $0 # auxv[1][1]=0
|
|
push $0 # auxv[1][0]=0
|
|
mov %rsp,%rcx # auxv
|
|
#endif
|
|
|
|
// enter cosmopolitan runtime
|
|
1: mov %ebx,%edi
|
|
call cosmo
|
|
9: .unreachable
|
|
.endfn _start,weak,hidden
|