mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-09-13 06:08:07 +00:00
c4fca4fdea
Correct a regression introduced with 8453eebd [MIPS: Fix strnlen_user() return value in case of overlong strings.] causing assembler warnings and broken code generated in __strnlen_kernel_nocheck_asm: arch/mips/lib/strnlen_user.S: Assembler messages: arch/mips/lib/strnlen_user.S:64: Warning: Macro instruction expanded into multiple instructions in a branch delay slot with the CPU_DADDI_WORKAROUNDS option set, resulting in the function looping indefinitely upon mounting NFS root. Use conditional assembly to avoid a microMIPS code size regression. Using $at unconditionally would cause such a regression as there are no 16-bit instruction encodings available for ALU operations using this register. Using $v1 unconditionally would produce short microMIPS encodings, but would prevent this register from being used across calls to this function. The extra LI operation introduced is free, replacing a NOP originally scheduled into the delay slot of the branch that follows. Signed-off-by: Maciej W. Rozycki <macro@linux-mips.org> Cc: linux-mips@linux-mips.org Patchwork: https://patchwork.linux-mips.org/patch/10205/ Signed-off-by: Ralf Baechle <ralf@linux-mips.org>
83 lines
1.8 KiB
ArmAsm
83 lines
1.8 KiB
ArmAsm
/*
|
|
* This file is subject to the terms and conditions of the GNU General Public
|
|
* License. See the file "COPYING" in the main directory of this archive
|
|
* for more details.
|
|
*
|
|
* Copyright (c) 1996, 1998, 1999, 2004 by Ralf Baechle
|
|
* Copyright (c) 1999 Silicon Graphics, Inc.
|
|
*/
|
|
#include <asm/asm.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/regdef.h>
|
|
|
|
#define EX(insn,reg,addr,handler) \
|
|
9: insn reg, addr; \
|
|
.section __ex_table,"a"; \
|
|
PTR 9b, handler; \
|
|
.previous
|
|
|
|
/*
|
|
* Return the size of a string including the ending NUL character up to a
|
|
* maximum of a1 or 0 in case of error.
|
|
*
|
|
* Note: for performance reasons we deliberately accept that a user may
|
|
* make strlen_user and strnlen_user access the first few KSEG0
|
|
* bytes. There's nothing secret there. On 64-bit accessing beyond
|
|
* the maximum is a tad hairier ...
|
|
*/
|
|
.macro __BUILD_STRNLEN_ASM func
|
|
LEAF(__strnlen_\func\()_asm)
|
|
LONG_L v0, TI_ADDR_LIMIT($28) # pointer ok?
|
|
and v0, a0
|
|
bnez v0, .Lfault\@
|
|
|
|
FEXPORT(__strnlen_\func\()_nocheck_asm)
|
|
move v0, a0
|
|
PTR_ADDU a1, a0 # stop pointer
|
|
1:
|
|
#ifdef CONFIG_CPU_DADDI_WORKAROUNDS
|
|
.set noat
|
|
li AT, 1
|
|
#endif
|
|
beq v0, a1, 1f # limit reached?
|
|
.ifeqs "\func", "kernel"
|
|
EX(lb, t0, (v0), .Lfault\@)
|
|
.else
|
|
EX(lbe, t0, (v0), .Lfault\@)
|
|
.endif
|
|
.set noreorder
|
|
bnez t0, 1b
|
|
1:
|
|
#ifndef CONFIG_CPU_DADDI_WORKAROUNDS
|
|
PTR_ADDIU v0, 1
|
|
#else
|
|
PTR_ADDU v0, AT
|
|
.set at
|
|
#endif
|
|
.set reorder
|
|
PTR_SUBU v0, a0
|
|
jr ra
|
|
END(__strnlen_\func\()_asm)
|
|
|
|
.Lfault\@:
|
|
move v0, zero
|
|
jr ra
|
|
.endm
|
|
|
|
#ifndef CONFIG_EVA
|
|
/* Set aliases */
|
|
.global __strnlen_user_asm
|
|
.global __strnlen_user_nocheck_asm
|
|
.set __strnlen_user_asm, __strnlen_kernel_asm
|
|
.set __strnlen_user_nocheck_asm, __strnlen_kernel_nocheck_asm
|
|
#endif
|
|
|
|
__BUILD_STRNLEN_ASM kernel
|
|
|
|
#ifdef CONFIG_EVA
|
|
|
|
.set push
|
|
.set eva
|
|
__BUILD_STRNLEN_ASM user
|
|
.set pop
|
|
#endif
|