mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-09-15 23:25:07 +00:00
453431a549
As said by Linus: A symmetric naming is only helpful if it implies symmetries in use. Otherwise it's actively misleading. In "kzalloc()", the z is meaningful and an important part of what the caller wants. In "kzfree()", the z is actively detrimental, because maybe in the future we really _might_ want to use that "memfill(0xdeadbeef)" or something. The "zero" part of the interface isn't even _relevant_. The main reason that kzfree() exists is to clear sensitive information that should not be leaked to other future users of the same memory objects. Rename kzfree() to kfree_sensitive() to follow the example of the recently added kvfree_sensitive() and make the intention of the API more explicit. In addition, memzero_explicit() is used to clear the memory to make sure that it won't get optimized away by the compiler. The renaming is done by using the command sequence: git grep -w --name-only kzfree |\ xargs sed -i 's/kzfree/kfree_sensitive/' followed by some editing of the kfree_sensitive() kerneldoc and adding a kzfree backward compatibility macro in slab.h. [akpm@linux-foundation.org: fs/crypto/inline_crypt.c needs linux/slab.h] [akpm@linux-foundation.org: fix fs/crypto/inline_crypt.c some more] Suggested-by: Joe Perches <joe@perches.com> Signed-off-by: Waiman Long <longman@redhat.com> Signed-off-by: Andrew Morton <akpm@linux-foundation.org> Acked-by: David Howells <dhowells@redhat.com> Acked-by: Michal Hocko <mhocko@suse.com> Acked-by: Johannes Weiner <hannes@cmpxchg.org> Cc: Jarkko Sakkinen <jarkko.sakkinen@linux.intel.com> Cc: James Morris <jmorris@namei.org> Cc: "Serge E. Hallyn" <serge@hallyn.com> Cc: Joe Perches <joe@perches.com> Cc: Matthew Wilcox <willy@infradead.org> Cc: David Rientjes <rientjes@google.com> Cc: Dan Carpenter <dan.carpenter@oracle.com> Cc: "Jason A . Donenfeld" <Jason@zx2c4.com> Link: http://lkml.kernel.org/r/20200616154311.12314-3-longman@redhat.com Signed-off-by: Linus Torvalds <torvalds@linux-foundation.org>
134 lines
1.8 KiB
Text
134 lines
1.8 KiB
Text
// SPDX-License-Identifier: GPL-2.0-only
|
|
/// Find a use after free.
|
|
//# Values of variables may imply that some
|
|
//# execution paths are not possible, resulting in false positives.
|
|
//# Another source of false positives are macros such as
|
|
//# SCTP_DBG_OBJCNT_DEC that do not actually evaluate their argument
|
|
///
|
|
// Confidence: Moderate
|
|
// Copyright: (C) 2010-2012 Nicolas Palix.
|
|
// Copyright: (C) 2010-2012 Julia Lawall, INRIA/LIP6.
|
|
// Copyright: (C) 2010-2012 Gilles Muller, INRIA/LiP6.
|
|
// URL: http://coccinelle.lip6.fr/
|
|
// Comments:
|
|
// Options: --no-includes --include-headers
|
|
|
|
virtual org
|
|
virtual report
|
|
|
|
@free@
|
|
expression E;
|
|
position p1;
|
|
@@
|
|
|
|
(
|
|
* kfree@p1(E)
|
|
|
|
|
* kfree_sensitive@p1(E)
|
|
)
|
|
|
|
@print expression@
|
|
constant char [] c;
|
|
expression free.E,E2;
|
|
type T;
|
|
position p;
|
|
identifier f;
|
|
@@
|
|
|
|
(
|
|
f(...,c,...,(T)E@p,...)
|
|
|
|
|
E@p == E2
|
|
|
|
|
E@p != E2
|
|
|
|
|
E2 == E@p
|
|
|
|
|
E2 != E@p
|
|
|
|
|
!E@p
|
|
|
|
|
E@p || ...
|
|
)
|
|
|
|
@sz@
|
|
expression free.E;
|
|
position p;
|
|
@@
|
|
|
|
sizeof(<+...E@p...+>)
|
|
|
|
@loop exists@
|
|
expression E;
|
|
identifier l;
|
|
position ok;
|
|
@@
|
|
|
|
while (1) { ...
|
|
(
|
|
* kfree@ok(E)
|
|
|
|
|
* kfree_sensitive@ok(E)
|
|
)
|
|
... when != break;
|
|
when != goto l;
|
|
when forall
|
|
}
|
|
|
|
@r exists@
|
|
expression free.E, subE<=free.E, E2;
|
|
expression E1;
|
|
iterator iter;
|
|
statement S;
|
|
position free.p1!=loop.ok,p2!={print.p,sz.p};
|
|
@@
|
|
|
|
(
|
|
* kfree@p1(E,...)
|
|
|
|
|
* kfree_sensitive@p1(E,...)
|
|
)
|
|
...
|
|
(
|
|
iter(...,subE,...) S // no use
|
|
|
|
|
list_remove_head(E1,subE,...)
|
|
|
|
|
subE = E2
|
|
|
|
|
subE++
|
|
|
|
|
++subE
|
|
|
|
|
--subE
|
|
|
|
|
subE--
|
|
|
|
|
&subE
|
|
|
|
|
BUG(...)
|
|
|
|
|
BUG_ON(...)
|
|
|
|
|
return_VALUE(...)
|
|
|
|
|
return_ACPI_STATUS(...)
|
|
|
|
|
E@p2 // bad use
|
|
)
|
|
|
|
@script:python depends on org@
|
|
p1 << free.p1;
|
|
p2 << r.p2;
|
|
@@
|
|
|
|
cocci.print_main("kfree",p1)
|
|
cocci.print_secs("ref",p2)
|
|
|
|
@script:python depends on report@
|
|
p1 << free.p1;
|
|
p2 << r.p2;
|
|
@@
|
|
|
|
msg = "ERROR: reference preceded by free on line %s" % (p1[0].line)
|
|
coccilib.report.print_report(p2[0],msg)
|