mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-08-27 11:19:37 +00:00
99bf73ebf9
System call table generation script must be run to gener- ate unistd_(nr_)n64/n32/o32.h and syscall_table_32_o32/ 64_n64/64_n32/64-o32.h files. This patch will have changes which will invokes the script. This patch will generate unistd_(nr_)n64/n32/o32.h and syscall_table_32_o32/64_n64/64-n32/64-o32.h files by the syscall table generation script invoked by parisc/Make- file and the generated files against the removed files must be identical. The generated uapi header file will be included in uapi/- asm/unistd.h and generated system call table header file will be included by kernel/scall32-o32/64-n64/64-n32/- 64-o32.Sfile. Signed-off-by: Firoz Khan <firoz.khan@linaro.org> Signed-off-by: Paul Burton <paul.burton@mips.com> Cc: linux-mips@vger.kernel.org Cc: Ralf Baechle <ralf@linux-mips.org> Cc: James Hogan <jhogan@kernel.org> Cc: Greg Kroah-Hartman <gregkh@linuxfoundation.org> Cc: Philippe Ombredanne <pombredanne@nexb.com> Cc: Thomas Gleixner <tglx@linutronix.de> Cc: Kate Stewart <kstewart@linuxfoundation.org> Cc: y2038@lists.linaro.org Cc: linux-kernel@vger.kernel.org Cc: linux-arch@vger.kernel.org Cc: arnd@arndb.de Cc: deepa.kernel@gmail.com Cc: marcin.juszkiewicz@linaro.org
108 lines
2.5 KiB
ArmAsm
108 lines
2.5 KiB
ArmAsm
/*
|
|
* This file is subject to the terms and conditions of the GNU General Public
|
|
* License. See the file "COPYING" in the main directory of this archive
|
|
* for more details.
|
|
*
|
|
* Copyright (C) 1995, 96, 97, 98, 99, 2000, 01 by Ralf Baechle
|
|
* Copyright (C) 1999, 2000 Silicon Graphics, Inc.
|
|
* Copyright (C) 2001 MIPS Technologies, Inc.
|
|
*/
|
|
#include <linux/errno.h>
|
|
#include <asm/asm.h>
|
|
#include <asm/asmmacro.h>
|
|
#include <asm/irqflags.h>
|
|
#include <asm/mipsregs.h>
|
|
#include <asm/regdef.h>
|
|
#include <asm/stackframe.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/unistd.h>
|
|
|
|
#ifndef CONFIG_MIPS32_O32
|
|
/* No O32, so define handle_sys here */
|
|
#define handle_sysn32 handle_sys
|
|
#endif
|
|
|
|
.align 5
|
|
NESTED(handle_sysn32, PT_SIZE, sp)
|
|
#ifndef CONFIG_MIPS32_O32
|
|
.set noat
|
|
SAVE_SOME
|
|
TRACE_IRQS_ON_RELOAD
|
|
STI
|
|
.set at
|
|
#endif
|
|
|
|
dsubu t0, v0, __NR_N32_Linux # check syscall number
|
|
sltiu t0, t0, __NR_N32_Linux_syscalls
|
|
|
|
#ifndef CONFIG_MIPS32_O32
|
|
ld t1, PT_EPC(sp) # skip syscall on return
|
|
daddiu t1, 4 # skip to next instruction
|
|
sd t1, PT_EPC(sp)
|
|
#endif
|
|
beqz t0, not_n32_scall
|
|
|
|
sd a3, PT_R26(sp) # save a3 for syscall restarting
|
|
|
|
li t1, _TIF_WORK_SYSCALL_ENTRY
|
|
LONG_L t0, TI_FLAGS($28) # syscall tracing enabled?
|
|
and t0, t1, t0
|
|
bnez t0, n32_syscall_trace_entry
|
|
|
|
syscall_common:
|
|
dsll t0, v0, 3 # offset into table
|
|
ld t2, (sysn32_call_table - (__NR_N32_Linux * 8))(t0)
|
|
|
|
jalr t2 # Do The Real Thing (TM)
|
|
|
|
li t0, -EMAXERRNO - 1 # error?
|
|
sltu t0, t0, v0
|
|
sd t0, PT_R7(sp) # set error flag
|
|
beqz t0, 1f
|
|
|
|
ld t1, PT_R2(sp) # syscall number
|
|
dnegu v0 # error
|
|
sd t1, PT_R0(sp) # save it for syscall restarting
|
|
1: sd v0, PT_R2(sp) # result
|
|
|
|
j syscall_exit_partial
|
|
|
|
/* ------------------------------------------------------------------------ */
|
|
|
|
n32_syscall_trace_entry:
|
|
SAVE_STATIC
|
|
move a0, sp
|
|
move a1, v0
|
|
jal syscall_trace_enter
|
|
|
|
bltz v0, 1f # seccomp failed? Skip syscall
|
|
|
|
RESTORE_STATIC
|
|
ld v0, PT_R2(sp) # Restore syscall (maybe modified)
|
|
ld a0, PT_R4(sp) # Restore argument registers
|
|
ld a1, PT_R5(sp)
|
|
ld a2, PT_R6(sp)
|
|
ld a3, PT_R7(sp)
|
|
ld a4, PT_R8(sp)
|
|
ld a5, PT_R9(sp)
|
|
|
|
dsubu t2, v0, __NR_N32_Linux # check (new) syscall number
|
|
sltiu t0, t2, __NR_N32_Linux_syscalls
|
|
beqz t0, not_n32_scall
|
|
|
|
j syscall_common
|
|
|
|
1: j syscall_exit
|
|
|
|
not_n32_scall:
|
|
/* This is not an n32 compatibility syscall, pass it on to
|
|
the n64 syscall handlers. */
|
|
j handle_sys64
|
|
|
|
END(handle_sysn32)
|
|
|
|
#define __SYSCALL(nr, entry, nargs) PTR entry
|
|
.type sysn32_call_table, @object
|
|
EXPORT(sysn32_call_table)
|
|
#include <asm/syscall_table_64_n32.h>
|
|
#undef __SYSCALL
|