mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-09-12 13:55:32 +00:00
![Ian Rogers](/assets/img/avatar_default.png)
Division by zero causes expression parsing to fail and no metric to be generated. This can mean for short running benchmarks metrics are not shown. Change the behavior to make the value nan, which gets shown like: ''' $ perf stat -M TopdownL2 true Performance counter stats for 'true': 1,031,492 INST_RETIRED.ANY # nan % tma_fetch_bandwidth # nan % tma_heavy_operations # nan % tma_light_operations 29,304 CPU_CLK_UNHALTED.REF_XCLK # nan % tma_fetch_latency # nan % tma_branch_mispredicts # nan % tma_machine_clears # nan % tma_core_bound # nan % tma_memory_bound 2,658,319 IDQ_UOPS_NOT_DELIVERED.CORE 11,167 EXE_ACTIVITY.BOUND_ON_STORES 262,058 EXE_ACTIVITY.1_PORTS_UTIL <not counted> BR_MISP_RETIRED.ALL_BRANCHES (0.00%) <not counted> INT_MISC.RECOVERY_CYCLES_ANY (0.00%) <not counted> CPU_CLK_UNHALTED.ONE_THREAD_ACTIVE (0.00%) <not counted> CPU_CLK_UNHALTED.THREAD (0.00%) <not counted> UOPS_RETIRED.RETIRE_SLOTS (0.00%) <not counted> CYCLE_ACTIVITY.STALLS_MEM_ANY (0.00%) <not counted> UOPS_RETIRED.MACRO_FUSED (0.00%) <not counted> IDQ_UOPS_NOT_DELIVERED.CYCLES_0_UOPS_DELIV.CORE (0.00%) <not counted> EXE_ACTIVITY.2_PORTS_UTIL (0.00%) <not counted> CYCLE_ACTIVITY.STALLS_TOTAL (0.00%) <not counted> MACHINE_CLEARS.COUNT (0.00%) <not counted> UOPS_ISSUED.ANY (0.00%) 0.002864879 seconds time elapsed 0.003012000 seconds user 0.000000000 seconds sys ''' When events aren't supported a count of 0 can be confusing and make metrics look meaningful. Change these to be nan also which, with the next change, gets shown like: ''' $ perf stat true Performance counter stats for 'true': 1.25 msec task-clock:u # 0.387 CPUs utilized 0 context-switches:u # 0.000 /sec 0 cpu-migrations:u # 0.000 /sec 46 page-faults:u # 36.702 K/sec 255,942 cycles:u # 0.204 GHz (88.66%) 123,046 instructions:u # 0.48 insn per cycle 28,301 branches:u # 22.580 M/sec 2,489 branch-misses:u # 8.79% of all branches 4,719 CPU_CLK_UNHALTED.REF_XCLK:u # 3.765 M/sec # nan % tma_frontend_bound # nan % tma_retiring # nan % tma_backend_bound # nan % tma_bad_speculation 344,855 IDQ_UOPS_NOT_DELIVERED.CORE:u # 275.147 M/sec <not supported> INT_MISC.RECOVERY_CYCLES_ANY:u <not counted> CPU_CLK_UNHALTED.ONE_THREAD_ACTIVE:u (0.00%) <not counted> CPU_CLK_UNHALTED.THREAD:u (0.00%) <not counted> UOPS_RETIRED.RETIRE_SLOTS:u (0.00%) <not counted> UOPS_ISSUED.ANY:u (0.00%) 0.003238142 seconds time elapsed 0.000000000 seconds user 0.003434000 seconds sys ''' Ensure that nan metric values are quoted as nan isn't a valid number in JSON. Signed-off-by: Ian Rogers <irogers@google.com> Tested-by: Kan Liang <kan.liang@linux.intel.com> Cc: Adrian Hunter <adrian.hunter@intel.com> Cc: Ahmad Yasin <ahmad.yasin@intel.com> Cc: Alexander Shishkin <alexander.shishkin@linux.intel.com> Cc: Andi Kleen <ak@linux.intel.com> Cc: Athira Rajeev <atrajeev@linux.vnet.ibm.com> Cc: Caleb Biggers <caleb.biggers@intel.com> Cc: Edward Baker <edward.baker@intel.com> Cc: Florian Fischer <florian.fischer@muhq.space> Cc: Ingo Molnar <mingo@redhat.com> Cc: James Clark <james.clark@arm.com> Cc: Jiri Olsa <jolsa@kernel.org> Cc: John Garry <john.g.garry@oracle.com> Cc: Kajol Jain <kjain@linux.ibm.com> Cc: Kang Minchul <tegongkang@gmail.com> Cc: Leo Yan <leo.yan@linaro.org> Cc: Mark Rutland <mark.rutland@arm.com> Cc: Namhyung Kim <namhyung@kernel.org> Cc: Perry Taylor <perry.taylor@intel.com> Cc: Peter Zijlstra <peterz@infradead.org> Cc: Ravi Bangoria <ravi.bangoria@amd.com> Cc: Rob Herring <robh@kernel.org> Cc: Samantha Alt <samantha.alt@intel.com> Cc: Stephane Eranian <eranian@google.com> Cc: Sumanth Korikkar <sumanthk@linux.ibm.com> Cc: Suzuki Poulouse <suzuki.poulose@arm.com> Cc: Thomas Richter <tmricht@linux.ibm.com> Cc: Tiezhu Yang <yangtiezhu@loongson.cn> Cc: Weilin Wang <weilin.wang@intel.com> Cc: Xing Zhengjun <zhengjun.xing@linux.intel.com> Cc: Yang Jihong <yangjihong1@huawei.com> Link: https://lore.kernel.org/r/20230502223851.2234828-2-irogers@google.com Signed-off-by: Arnaldo Carvalho de Melo <acme@redhat.com>
313 lines
7.2 KiB
Text
313 lines
7.2 KiB
Text
/* Simple expression parser */
|
|
%{
|
|
#define YYDEBUG 1
|
|
#include <assert.h>
|
|
#include <math.h>
|
|
#include <stdlib.h>
|
|
#include "util/debug.h"
|
|
#define IN_EXPR_Y 1
|
|
#include "expr.h"
|
|
%}
|
|
|
|
%define api.pure full
|
|
|
|
%parse-param { double *final_val }
|
|
%parse-param { struct expr_parse_ctx *ctx }
|
|
%parse-param { bool compute_ids }
|
|
%parse-param {void *scanner}
|
|
%lex-param {void* scanner}
|
|
|
|
%union {
|
|
double num;
|
|
char *str;
|
|
struct ids {
|
|
/*
|
|
* When creating ids, holds the working set of event ids. NULL
|
|
* implies the set is empty.
|
|
*/
|
|
struct hashmap *ids;
|
|
/*
|
|
* The metric value. When not creating ids this is the value
|
|
* read from a counter, a constant or some computed value. When
|
|
* creating ids the value is either a constant or BOTTOM. NAN is
|
|
* used as the special BOTTOM value, representing a "set of all
|
|
* values" case.
|
|
*/
|
|
double val;
|
|
} ids;
|
|
}
|
|
|
|
%token ID NUMBER MIN MAX IF ELSE LITERAL D_RATIO SOURCE_COUNT EXPR_ERROR
|
|
%left MIN MAX IF
|
|
%left '|'
|
|
%left '^'
|
|
%left '&'
|
|
%left '<' '>'
|
|
%left '-' '+'
|
|
%left '*' '/' '%'
|
|
%left NEG NOT
|
|
%type <num> NUMBER LITERAL
|
|
%type <str> ID
|
|
%destructor { free ($$); } <str>
|
|
%type <ids> expr if_expr
|
|
%destructor { ids__free($$.ids); } <ids>
|
|
|
|
%{
|
|
static void expr_error(double *final_val __maybe_unused,
|
|
struct expr_parse_ctx *ctx __maybe_unused,
|
|
bool compute_ids __maybe_unused,
|
|
void *scanner,
|
|
const char *s)
|
|
{
|
|
pr_debug("%s\n", s);
|
|
}
|
|
|
|
/*
|
|
* During compute ids, the special "bottom" value uses NAN to represent the set
|
|
* of all values. NAN is selected as it isn't a useful constant value.
|
|
*/
|
|
#define BOTTOM NAN
|
|
|
|
/* During computing ids, does val represent a constant (non-BOTTOM) value? */
|
|
static bool is_const(double val)
|
|
{
|
|
return isfinite(val);
|
|
}
|
|
|
|
static struct ids union_expr(struct ids ids1, struct ids ids2)
|
|
{
|
|
struct ids result = {
|
|
.val = BOTTOM,
|
|
.ids = ids__union(ids1.ids, ids2.ids),
|
|
};
|
|
return result;
|
|
}
|
|
|
|
static struct ids handle_id(struct expr_parse_ctx *ctx, char *id,
|
|
bool compute_ids, bool source_count)
|
|
{
|
|
struct ids result;
|
|
|
|
if (!compute_ids) {
|
|
/*
|
|
* Compute the event's value from ID. If the ID isn't known then
|
|
* it isn't used to compute the formula so set to NAN.
|
|
*/
|
|
struct expr_id_data *data;
|
|
|
|
result.val = NAN;
|
|
if (expr__resolve_id(ctx, id, &data) == 0) {
|
|
result.val = source_count
|
|
? expr_id_data__source_count(data)
|
|
: expr_id_data__value(data);
|
|
}
|
|
result.ids = NULL;
|
|
free(id);
|
|
} else {
|
|
/*
|
|
* Set the value to BOTTOM to show that any value is possible
|
|
* when the event is computed. Create a set of just the ID.
|
|
*/
|
|
result.val = BOTTOM;
|
|
result.ids = ids__new();
|
|
if (!result.ids || ids__insert(result.ids, id)) {
|
|
pr_err("Error creating IDs for '%s'", id);
|
|
free(id);
|
|
}
|
|
}
|
|
return result;
|
|
}
|
|
|
|
/*
|
|
* If we're not computing ids or $1 and $3 are constants, compute the new
|
|
* constant value using OP. Its invariant that there are no ids. If computing
|
|
* ids for non-constants union the set of IDs that must be computed.
|
|
*/
|
|
#define BINARY_LONG_OP(RESULT, OP, LHS, RHS) \
|
|
if (!compute_ids || (is_const(LHS.val) && is_const(RHS.val))) { \
|
|
assert(LHS.ids == NULL); \
|
|
assert(RHS.ids == NULL); \
|
|
if (isnan(LHS.val) || isnan(RHS.val)) { \
|
|
RESULT.val = NAN; \
|
|
} else { \
|
|
RESULT.val = (long)LHS.val OP (long)RHS.val; \
|
|
} \
|
|
RESULT.ids = NULL; \
|
|
} else { \
|
|
RESULT = union_expr(LHS, RHS); \
|
|
}
|
|
|
|
#define BINARY_OP(RESULT, OP, LHS, RHS) \
|
|
if (!compute_ids || (is_const(LHS.val) && is_const(RHS.val))) { \
|
|
assert(LHS.ids == NULL); \
|
|
assert(RHS.ids == NULL); \
|
|
if (isnan(LHS.val) || isnan(RHS.val)) { \
|
|
RESULT.val = NAN; \
|
|
} else { \
|
|
RESULT.val = LHS.val OP RHS.val; \
|
|
} \
|
|
RESULT.ids = NULL; \
|
|
} else { \
|
|
RESULT = union_expr(LHS, RHS); \
|
|
}
|
|
|
|
%}
|
|
%%
|
|
|
|
start: if_expr
|
|
{
|
|
if (compute_ids)
|
|
ctx->ids = ids__union($1.ids, ctx->ids);
|
|
|
|
if (final_val)
|
|
*final_val = $1.val;
|
|
}
|
|
;
|
|
|
|
if_expr: expr IF expr ELSE if_expr
|
|
{
|
|
if (fpclassify($3.val) == FP_ZERO) {
|
|
/*
|
|
* The IF expression evaluated to 0 so treat as false, take the
|
|
* ELSE and discard everything else.
|
|
*/
|
|
$$.val = $5.val;
|
|
$$.ids = $5.ids;
|
|
ids__free($1.ids);
|
|
ids__free($3.ids);
|
|
} else if (!compute_ids || is_const($3.val)) {
|
|
/*
|
|
* If ids aren't computed then treat the expression as true. If
|
|
* ids are being computed and the IF expr is a non-zero
|
|
* constant, then also evaluate the true case.
|
|
*/
|
|
$$.val = $1.val;
|
|
$$.ids = $1.ids;
|
|
ids__free($3.ids);
|
|
ids__free($5.ids);
|
|
} else if ($1.val == $5.val) {
|
|
/*
|
|
* LHS == RHS, so both are an identical constant. No need to
|
|
* evaluate any events.
|
|
*/
|
|
$$.val = $1.val;
|
|
$$.ids = NULL;
|
|
ids__free($1.ids);
|
|
ids__free($3.ids);
|
|
ids__free($5.ids);
|
|
} else {
|
|
/*
|
|
* Value is either the LHS or RHS and we need the IF expression
|
|
* to compute it.
|
|
*/
|
|
$$ = union_expr($1, union_expr($3, $5));
|
|
}
|
|
}
|
|
| expr
|
|
;
|
|
|
|
expr: NUMBER
|
|
{
|
|
$$.val = $1;
|
|
$$.ids = NULL;
|
|
}
|
|
| ID { $$ = handle_id(ctx, $1, compute_ids, /*source_count=*/false); }
|
|
| SOURCE_COUNT '(' ID ')' { $$ = handle_id(ctx, $3, compute_ids, /*source_count=*/true); }
|
|
| expr '|' expr { BINARY_LONG_OP($$, |, $1, $3); }
|
|
| expr '&' expr { BINARY_LONG_OP($$, &, $1, $3); }
|
|
| expr '^' expr { BINARY_LONG_OP($$, ^, $1, $3); }
|
|
| expr '<' expr { BINARY_OP($$, <, $1, $3); }
|
|
| expr '>' expr { BINARY_OP($$, >, $1, $3); }
|
|
| expr '+' expr { BINARY_OP($$, +, $1, $3); }
|
|
| expr '-' expr { BINARY_OP($$, -, $1, $3); }
|
|
| expr '*' expr { BINARY_OP($$, *, $1, $3); }
|
|
| expr '/' expr
|
|
{
|
|
if (fpclassify($3.val) == FP_ZERO) {
|
|
pr_debug("division by zero\n");
|
|
assert($3.ids == NULL);
|
|
if (compute_ids)
|
|
ids__free($1.ids);
|
|
$$.val = NAN;
|
|
$$.ids = NULL;
|
|
} else if (!compute_ids || (is_const($1.val) && is_const($3.val))) {
|
|
assert($1.ids == NULL);
|
|
assert($3.ids == NULL);
|
|
$$.val = $1.val / $3.val;
|
|
$$.ids = NULL;
|
|
} else {
|
|
/* LHS and/or RHS need computing from event IDs so union. */
|
|
$$ = union_expr($1, $3);
|
|
}
|
|
}
|
|
| expr '%' expr
|
|
{
|
|
if (fpclassify($3.val) == FP_ZERO) {
|
|
pr_debug("division by zero\n");
|
|
YYABORT;
|
|
} else if (!compute_ids || (is_const($1.val) && is_const($3.val))) {
|
|
assert($1.ids == NULL);
|
|
assert($3.ids == NULL);
|
|
$$.val = (long)$1.val % (long)$3.val;
|
|
$$.ids = NULL;
|
|
} else {
|
|
/* LHS and/or RHS need computing from event IDs so union. */
|
|
$$ = union_expr($1, $3);
|
|
}
|
|
}
|
|
| D_RATIO '(' expr ',' expr ')'
|
|
{
|
|
if (fpclassify($5.val) == FP_ZERO) {
|
|
/*
|
|
* Division by constant zero always yields zero and no events
|
|
* are necessary.
|
|
*/
|
|
assert($5.ids == NULL);
|
|
$$.val = 0.0;
|
|
$$.ids = NULL;
|
|
ids__free($3.ids);
|
|
} else if (!compute_ids || (is_const($3.val) && is_const($5.val))) {
|
|
assert($3.ids == NULL);
|
|
assert($5.ids == NULL);
|
|
$$.val = $3.val / $5.val;
|
|
$$.ids = NULL;
|
|
} else {
|
|
/* LHS and/or RHS need computing from event IDs so union. */
|
|
$$ = union_expr($3, $5);
|
|
}
|
|
}
|
|
| '-' expr %prec NEG
|
|
{
|
|
$$.val = -$2.val;
|
|
$$.ids = $2.ids;
|
|
}
|
|
| '(' if_expr ')'
|
|
{
|
|
$$ = $2;
|
|
}
|
|
| MIN '(' expr ',' expr ')'
|
|
{
|
|
if (!compute_ids) {
|
|
$$.val = $3.val < $5.val ? $3.val : $5.val;
|
|
$$.ids = NULL;
|
|
} else {
|
|
$$ = union_expr($3, $5);
|
|
}
|
|
}
|
|
| MAX '(' expr ',' expr ')'
|
|
{
|
|
if (!compute_ids) {
|
|
$$.val = $3.val > $5.val ? $3.val : $5.val;
|
|
$$.ids = NULL;
|
|
} else {
|
|
$$ = union_expr($3, $5);
|
|
}
|
|
}
|
|
| LITERAL
|
|
{
|
|
$$.val = $1;
|
|
$$.ids = NULL;
|
|
}
|
|
;
|
|
|
|
%%
|