mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-09-30 06:10:56 +00:00
f94909ceb1
Replace all ret/retq instructions with RET in preparation of making RET a macro. Since AS is case insensitive it's a big no-op without RET defined. find arch/x86/ -name \*.S | while read file do sed -i 's/\<ret[q]*\>/RET/' $file done Signed-off-by: Peter Zijlstra (Intel) <peterz@infradead.org> Signed-off-by: Borislav Petkov <bp@suse.de> Link: https://lore.kernel.org/r/20211204134907.905503893@infradead.org
52 lines
993 B
ArmAsm
52 lines
993 B
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
#include <linux/linkage.h>
|
|
#include <asm/export.h>
|
|
|
|
/*
|
|
* Most CPUs support enhanced REP MOVSB/STOSB instructions. It is
|
|
* recommended to use this when possible and we do use them by default.
|
|
* If enhanced REP MOVSB/STOSB is not available, try to use fast string.
|
|
* Otherwise, use original.
|
|
*/
|
|
|
|
/*
|
|
* Zero a page.
|
|
* %rdi - page
|
|
*/
|
|
SYM_FUNC_START(clear_page_rep)
|
|
movl $4096/8,%ecx
|
|
xorl %eax,%eax
|
|
rep stosq
|
|
RET
|
|
SYM_FUNC_END(clear_page_rep)
|
|
EXPORT_SYMBOL_GPL(clear_page_rep)
|
|
|
|
SYM_FUNC_START(clear_page_orig)
|
|
xorl %eax,%eax
|
|
movl $4096/64,%ecx
|
|
.p2align 4
|
|
.Lloop:
|
|
decl %ecx
|
|
#define PUT(x) movq %rax,x*8(%rdi)
|
|
movq %rax,(%rdi)
|
|
PUT(1)
|
|
PUT(2)
|
|
PUT(3)
|
|
PUT(4)
|
|
PUT(5)
|
|
PUT(6)
|
|
PUT(7)
|
|
leaq 64(%rdi),%rdi
|
|
jnz .Lloop
|
|
nop
|
|
RET
|
|
SYM_FUNC_END(clear_page_orig)
|
|
EXPORT_SYMBOL_GPL(clear_page_orig)
|
|
|
|
SYM_FUNC_START(clear_page_erms)
|
|
movl $4096,%ecx
|
|
xorl %eax,%eax
|
|
rep stosb
|
|
RET
|
|
SYM_FUNC_END(clear_page_erms)
|
|
EXPORT_SYMBOL_GPL(clear_page_erms)
|