mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-09-21 10:01:00 +00:00
8e86f0b409
Linux requires a number of atomic operations to provide full barrier
semantics, that is no memory accesses after the operation can be
observed before any accesses up to and including the operation in
program order.
On arm64, these operations have been incorrectly implemented as follows:
// A, B, C are independent memory locations
<Access [A]>
// atomic_op (B)
1: ldaxr x0, [B] // Exclusive load with acquire
<op(B)>
stlxr w1, x0, [B] // Exclusive store with release
cbnz w1, 1b
<Access [C]>
The assumption here being that two half barriers are equivalent to a
full barrier, so the only permitted ordering would be A -> B -> C
(where B is the atomic operation involving both a load and a store).
Unfortunately, this is not the case by the letter of the architecture
and, in fact, the accesses to A and C are permitted to pass their
nearest half barrier resulting in orderings such as Bl -> A -> C -> Bs
or Bl -> C -> A -> Bs (where Bl is the load-acquire on B and Bs is the
store-release on B). This is a clear violation of the full barrier
requirement.
The simple way to fix this is to implement the same algorithm as ARMv7
using explicit barriers:
<Access [A]>
// atomic_op (B)
dmb ish // Full barrier
1: ldxr x0, [B] // Exclusive load
<op(B)>
stxr w1, x0, [B] // Exclusive store
cbnz w1, 1b
dmb ish // Full barrier
<Access [C]>
but this has the undesirable effect of introducing *two* full barrier
instructions. A better approach is actually the following, non-intuitive
sequence:
<Access [A]>
// atomic_op (B)
1: ldxr x0, [B] // Exclusive load
<op(B)>
stlxr w1, x0, [B] // Exclusive store with release
cbnz w1, 1b
dmb ish // Full barrier
<Access [C]>
The simple observations here are:
- The dmb ensures that no subsequent accesses (e.g. the access to C)
can enter or pass the atomic sequence.
- The dmb also ensures that no prior accesses (e.g. the access to A)
can pass the atomic sequence.
- Therefore, no prior access can pass a subsequent access, or
vice-versa (i.e. A is strictly ordered before C).
- The stlxr ensures that no prior access can pass the store component
of the atomic operation.
The only tricky part remaining is the ordering between the ldxr and the
access to A, since the absence of the first dmb means that we're now
permitting re-ordering between the ldxr and any prior accesses.
From an (arbitrary) observer's point of view, there are two scenarios:
1. We have observed the ldxr. This means that if we perform a store to
[B], the ldxr will still return older data. If we can observe the
ldxr, then we can potentially observe the permitted re-ordering
with the access to A, which is clearly an issue when compared to
the dmb variant of the code. Thankfully, the exclusive monitor will
save us here since it will be cleared as a result of the store and
the ldxr will retry. Notice that any use of a later memory
observation to imply observation of the ldxr will also imply
observation of the access to A, since the stlxr/dmb ensure strict
ordering.
2. We have not observed the ldxr. This means we can perform a store
and influence the later ldxr. However, that doesn't actually tell
us anything about the access to [A], so we've not lost anything
here either when compared to the dmb variant.
This patch implements this solution for our barriered atomic operations,
ensuring that we satisfy the full barrier requirements where they are
needed.
Cc: <stable@vger.kernel.org>
Cc: Peter Zijlstra <peterz@infradead.org>
Signed-off-by: Will Deacon <will.deacon@arm.com>
Signed-off-by: Catalin Marinas <catalin.marinas@arm.com>
69 lines
1.6 KiB
ArmAsm
69 lines
1.6 KiB
ArmAsm
/*
|
|
* Based on arch/arm/lib/bitops.h
|
|
*
|
|
* Copyright (C) 2013 ARM Ltd.
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
|
|
/*
|
|
* x0: bits 5:0 bit offset
|
|
* bits 31:6 word offset
|
|
* x1: address
|
|
*/
|
|
.macro bitop, name, instr
|
|
ENTRY( \name )
|
|
and w3, w0, #63 // Get bit offset
|
|
eor w0, w0, w3 // Clear low bits
|
|
mov x2, #1
|
|
add x1, x1, x0, lsr #3 // Get word offset
|
|
lsl x3, x2, x3 // Create mask
|
|
1: ldxr x2, [x1]
|
|
\instr x2, x2, x3
|
|
stxr w0, x2, [x1]
|
|
cbnz w0, 1b
|
|
ret
|
|
ENDPROC(\name )
|
|
.endm
|
|
|
|
.macro testop, name, instr
|
|
ENTRY( \name )
|
|
and w3, w0, #63 // Get bit offset
|
|
eor w0, w0, w3 // Clear low bits
|
|
mov x2, #1
|
|
add x1, x1, x0, lsr #3 // Get word offset
|
|
lsl x4, x2, x3 // Create mask
|
|
1: ldxr x2, [x1]
|
|
lsr x0, x2, x3 // Save old value of bit
|
|
\instr x2, x2, x4 // toggle bit
|
|
stlxr w5, x2, [x1]
|
|
cbnz w5, 1b
|
|
dmb ish
|
|
and x0, x0, #1
|
|
3: ret
|
|
ENDPROC(\name )
|
|
.endm
|
|
|
|
/*
|
|
* Atomic bit operations.
|
|
*/
|
|
bitop change_bit, eor
|
|
bitop clear_bit, bic
|
|
bitop set_bit, orr
|
|
|
|
testop test_and_change_bit, eor
|
|
testop test_and_clear_bit, bic
|
|
testop test_and_set_bit, orr
|