mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-08-20 14:16:02 +00:00
![Greg Kroah-Hartman](/assets/img/avatar_default.png)
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
306 lines
7.7 KiB
ArmAsm
306 lines
7.7 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* PAL Firmware support
|
|
* IA-64 Processor Programmers Reference Vol 2
|
|
*
|
|
* Copyright (C) 1999 Don Dugger <don.dugger@intel.com>
|
|
* Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
|
|
* Copyright (C) 1999-2001, 2003 Hewlett-Packard Co
|
|
* David Mosberger <davidm@hpl.hp.com>
|
|
* Stephane Eranian <eranian@hpl.hp.com>
|
|
*
|
|
* 05/22/2000 eranian Added support for stacked register calls
|
|
* 05/24/2000 eranian Added support for physical mode static calls
|
|
*/
|
|
|
|
#include <asm/asmmacro.h>
|
|
#include <asm/processor.h>
|
|
#include <asm/export.h>
|
|
|
|
.data
|
|
pal_entry_point:
|
|
data8 ia64_pal_default_handler
|
|
.text
|
|
|
|
/*
|
|
* Set the PAL entry point address. This could be written in C code, but we
|
|
* do it here to keep it all in one module (besides, it's so trivial that it's
|
|
* not a big deal).
|
|
*
|
|
* in0 Address of the PAL entry point (text address, NOT a function
|
|
* descriptor).
|
|
*/
|
|
GLOBAL_ENTRY(ia64_pal_handler_init)
|
|
alloc r3=ar.pfs,1,0,0,0
|
|
movl r2=pal_entry_point
|
|
;;
|
|
st8 [r2]=in0
|
|
br.ret.sptk.many rp
|
|
END(ia64_pal_handler_init)
|
|
|
|
/*
|
|
* Default PAL call handler. This needs to be coded in assembly because it
|
|
* uses the static calling convention, i.e., the RSE may not be used and
|
|
* calls are done via "br.cond" (not "br.call").
|
|
*/
|
|
GLOBAL_ENTRY(ia64_pal_default_handler)
|
|
mov r8=-1
|
|
br.cond.sptk.many rp
|
|
END(ia64_pal_default_handler)
|
|
|
|
/*
|
|
* Make a PAL call using the static calling convention.
|
|
*
|
|
* in0 Index of PAL service
|
|
* in1 - in3 Remaining PAL arguments
|
|
*/
|
|
GLOBAL_ENTRY(ia64_pal_call_static)
|
|
.prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(4)
|
|
alloc loc1 = ar.pfs,4,5,0,0
|
|
movl loc2 = pal_entry_point
|
|
1: {
|
|
mov r28 = in0
|
|
mov r29 = in1
|
|
mov r8 = ip
|
|
}
|
|
;;
|
|
ld8 loc2 = [loc2] // loc2 <- entry point
|
|
adds r8 = 1f-1b,r8
|
|
mov loc4=ar.rsc // save RSE configuration
|
|
;;
|
|
mov ar.rsc=0 // put RSE in enforced lazy, LE mode
|
|
mov loc3 = psr
|
|
mov loc0 = rp
|
|
.body
|
|
mov r30 = in2
|
|
|
|
mov r31 = in3
|
|
mov b7 = loc2
|
|
|
|
rsm psr.i
|
|
;;
|
|
mov rp = r8
|
|
br.cond.sptk.many b7
|
|
1: mov psr.l = loc3
|
|
mov ar.rsc = loc4 // restore RSE configuration
|
|
mov ar.pfs = loc1
|
|
mov rp = loc0
|
|
;;
|
|
srlz.d // seralize restoration of psr.l
|
|
br.ret.sptk.many b0
|
|
END(ia64_pal_call_static)
|
|
EXPORT_SYMBOL(ia64_pal_call_static)
|
|
|
|
/*
|
|
* Make a PAL call using the stacked registers calling convention.
|
|
*
|
|
* Inputs:
|
|
* in0 Index of PAL service
|
|
* in2 - in3 Remaining PAL arguments
|
|
*/
|
|
GLOBAL_ENTRY(ia64_pal_call_stacked)
|
|
.prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(4)
|
|
alloc loc1 = ar.pfs,4,4,4,0
|
|
movl loc2 = pal_entry_point
|
|
|
|
mov r28 = in0 // Index MUST be copied to r28
|
|
mov out0 = in0 // AND in0 of PAL function
|
|
mov loc0 = rp
|
|
.body
|
|
;;
|
|
ld8 loc2 = [loc2] // loc2 <- entry point
|
|
mov out1 = in1
|
|
mov out2 = in2
|
|
mov out3 = in3
|
|
mov loc3 = psr
|
|
;;
|
|
rsm psr.i
|
|
mov b7 = loc2
|
|
;;
|
|
br.call.sptk.many rp=b7 // now make the call
|
|
.ret0: mov psr.l = loc3
|
|
mov ar.pfs = loc1
|
|
mov rp = loc0
|
|
;;
|
|
srlz.d // serialize restoration of psr.l
|
|
br.ret.sptk.many b0
|
|
END(ia64_pal_call_stacked)
|
|
EXPORT_SYMBOL(ia64_pal_call_stacked)
|
|
|
|
/*
|
|
* Make a physical mode PAL call using the static registers calling convention.
|
|
*
|
|
* Inputs:
|
|
* in0 Index of PAL service
|
|
* in2 - in3 Remaining PAL arguments
|
|
*
|
|
* PSR_LP, PSR_TB, PSR_ID, PSR_DA are never set by the kernel.
|
|
* So we don't need to clear them.
|
|
*/
|
|
#define PAL_PSR_BITS_TO_CLEAR \
|
|
(IA64_PSR_I | IA64_PSR_IT | IA64_PSR_DT | IA64_PSR_DB | IA64_PSR_RT |\
|
|
IA64_PSR_DD | IA64_PSR_SS | IA64_PSR_RI | IA64_PSR_ED | \
|
|
IA64_PSR_DFL | IA64_PSR_DFH)
|
|
|
|
#define PAL_PSR_BITS_TO_SET \
|
|
(IA64_PSR_BN)
|
|
|
|
|
|
GLOBAL_ENTRY(ia64_pal_call_phys_static)
|
|
.prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(4)
|
|
alloc loc1 = ar.pfs,4,7,0,0
|
|
movl loc2 = pal_entry_point
|
|
1: {
|
|
mov r28 = in0 // copy procedure index
|
|
mov r8 = ip // save ip to compute branch
|
|
mov loc0 = rp // save rp
|
|
}
|
|
.body
|
|
;;
|
|
ld8 loc2 = [loc2] // loc2 <- entry point
|
|
mov r29 = in1 // first argument
|
|
mov r30 = in2 // copy arg2
|
|
mov r31 = in3 // copy arg3
|
|
;;
|
|
mov loc3 = psr // save psr
|
|
adds r8 = 1f-1b,r8 // calculate return address for call
|
|
;;
|
|
mov loc4=ar.rsc // save RSE configuration
|
|
dep.z loc2=loc2,0,61 // convert pal entry point to physical
|
|
tpa r8=r8 // convert rp to physical
|
|
;;
|
|
mov b7 = loc2 // install target to branch reg
|
|
mov ar.rsc=0 // put RSE in enforced lazy, LE mode
|
|
movl r16=PAL_PSR_BITS_TO_CLEAR
|
|
movl r17=PAL_PSR_BITS_TO_SET
|
|
;;
|
|
or loc3=loc3,r17 // add in psr the bits to set
|
|
;;
|
|
andcm r16=loc3,r16 // removes bits to clear from psr
|
|
br.call.sptk.many rp=ia64_switch_mode_phys
|
|
mov rp = r8 // install return address (physical)
|
|
mov loc5 = r19
|
|
mov loc6 = r20
|
|
br.cond.sptk.many b7
|
|
1:
|
|
mov ar.rsc=0 // put RSE in enforced lazy, LE mode
|
|
mov r16=loc3 // r16= original psr
|
|
mov r19=loc5
|
|
mov r20=loc6
|
|
br.call.sptk.many rp=ia64_switch_mode_virt // return to virtual mode
|
|
mov psr.l = loc3 // restore init PSR
|
|
|
|
mov ar.pfs = loc1
|
|
mov rp = loc0
|
|
;;
|
|
mov ar.rsc=loc4 // restore RSE configuration
|
|
srlz.d // seralize restoration of psr.l
|
|
br.ret.sptk.many b0
|
|
END(ia64_pal_call_phys_static)
|
|
EXPORT_SYMBOL(ia64_pal_call_phys_static)
|
|
|
|
/*
|
|
* Make a PAL call using the stacked registers in physical mode.
|
|
*
|
|
* Inputs:
|
|
* in0 Index of PAL service
|
|
* in2 - in3 Remaining PAL arguments
|
|
*/
|
|
GLOBAL_ENTRY(ia64_pal_call_phys_stacked)
|
|
.prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(5)
|
|
alloc loc1 = ar.pfs,5,7,4,0
|
|
movl loc2 = pal_entry_point
|
|
1: {
|
|
mov r28 = in0 // copy procedure index
|
|
mov loc0 = rp // save rp
|
|
}
|
|
.body
|
|
;;
|
|
ld8 loc2 = [loc2] // loc2 <- entry point
|
|
mov loc3 = psr // save psr
|
|
;;
|
|
mov loc4=ar.rsc // save RSE configuration
|
|
dep.z loc2=loc2,0,61 // convert pal entry point to physical
|
|
;;
|
|
mov ar.rsc=0 // put RSE in enforced lazy, LE mode
|
|
movl r16=PAL_PSR_BITS_TO_CLEAR
|
|
movl r17=PAL_PSR_BITS_TO_SET
|
|
;;
|
|
or loc3=loc3,r17 // add in psr the bits to set
|
|
mov b7 = loc2 // install target to branch reg
|
|
;;
|
|
andcm r16=loc3,r16 // removes bits to clear from psr
|
|
br.call.sptk.many rp=ia64_switch_mode_phys
|
|
|
|
mov out0 = in0 // first argument
|
|
mov out1 = in1 // copy arg2
|
|
mov out2 = in2 // copy arg3
|
|
mov out3 = in3 // copy arg3
|
|
mov loc5 = r19
|
|
mov loc6 = r20
|
|
|
|
br.call.sptk.many rp=b7 // now make the call
|
|
|
|
mov ar.rsc=0 // put RSE in enforced lazy, LE mode
|
|
mov r16=loc3 // r16= original psr
|
|
mov r19=loc5
|
|
mov r20=loc6
|
|
br.call.sptk.many rp=ia64_switch_mode_virt // return to virtual mode
|
|
|
|
mov psr.l = loc3 // restore init PSR
|
|
mov ar.pfs = loc1
|
|
mov rp = loc0
|
|
;;
|
|
mov ar.rsc=loc4 // restore RSE configuration
|
|
srlz.d // seralize restoration of psr.l
|
|
br.ret.sptk.many b0
|
|
END(ia64_pal_call_phys_stacked)
|
|
EXPORT_SYMBOL(ia64_pal_call_phys_stacked)
|
|
|
|
/*
|
|
* Save scratch fp scratch regs which aren't saved in pt_regs already
|
|
* (fp10-fp15).
|
|
*
|
|
* NOTE: We need to do this since firmware (SAL and PAL) may use any of the
|
|
* scratch regs fp-low partition.
|
|
*
|
|
* Inputs:
|
|
* in0 Address of stack storage for fp regs
|
|
*/
|
|
GLOBAL_ENTRY(ia64_save_scratch_fpregs)
|
|
alloc r3=ar.pfs,1,0,0,0
|
|
add r2=16,in0
|
|
;;
|
|
stf.spill [in0] = f10,32
|
|
stf.spill [r2] = f11,32
|
|
;;
|
|
stf.spill [in0] = f12,32
|
|
stf.spill [r2] = f13,32
|
|
;;
|
|
stf.spill [in0] = f14,32
|
|
stf.spill [r2] = f15,32
|
|
br.ret.sptk.many rp
|
|
END(ia64_save_scratch_fpregs)
|
|
EXPORT_SYMBOL(ia64_save_scratch_fpregs)
|
|
|
|
/*
|
|
* Load scratch fp scratch regs (fp10-fp15)
|
|
*
|
|
* Inputs:
|
|
* in0 Address of stack storage for fp regs
|
|
*/
|
|
GLOBAL_ENTRY(ia64_load_scratch_fpregs)
|
|
alloc r3=ar.pfs,1,0,0,0
|
|
add r2=16,in0
|
|
;;
|
|
ldf.fill f10 = [in0],32
|
|
ldf.fill f11 = [r2],32
|
|
;;
|
|
ldf.fill f12 = [in0],32
|
|
ldf.fill f13 = [r2],32
|
|
;;
|
|
ldf.fill f14 = [in0],32
|
|
ldf.fill f15 = [r2],32
|
|
br.ret.sptk.many rp
|
|
END(ia64_load_scratch_fpregs)
|
|
EXPORT_SYMBOL(ia64_load_scratch_fpregs)
|