mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-08-23 17:30:02 +00:00
![Arvind Sankar](/assets/img/avatar_default.png)
GCC puts the main function into .text.startup when compiled with -Os (or -O2). This results in arch/x86/boot/main.c having a .text.startup section which is currently not included explicitly in the linker script setup.ld in the same directory. The BFD linker places this orphan section immediately after .text, so this still works. However, LLD git, since [1], is choosing to place it immediately after the .bstext section instead (this is the first code section). This plays havoc with the section layout that setup.elf requires to create the setup header, for eg on 64-bit: LD arch/x86/boot/setup.elf ld.lld: error: section .text.startup file range overlaps with .header >>> .text.startup range is [0x200040, 0x2001FE] >>> .header range is [0x2001EF, 0x20026B] ld.lld: error: section .header file range overlaps with .bsdata >>> .header range is [0x2001EF, 0x20026B] >>> .bsdata range is [0x2001FF, 0x200398] ld.lld: error: section .bsdata file range overlaps with .entrytext >>> .bsdata range is [0x2001FF, 0x200398] >>> .entrytext range is [0x20026C, 0x2002D3] ld.lld: error: section .text.startup virtual address range overlaps with .header >>> .text.startup range is [0x40, 0x1FE] >>> .header range is [0x1EF, 0x26B] ld.lld: error: section .header virtual address range overlaps with .bsdata >>> .header range is [0x1EF, 0x26B] >>> .bsdata range is [0x1FF, 0x398] ld.lld: error: section .bsdata virtual address range overlaps with .entrytext >>> .bsdata range is [0x1FF, 0x398] >>> .entrytext range is [0x26C, 0x2D3] ld.lld: error: section .text.startup load address range overlaps with .header >>> .text.startup range is [0x40, 0x1FE] >>> .header range is [0x1EF, 0x26B] ld.lld: error: section .header load address range overlaps with .bsdata >>> .header range is [0x1EF, 0x26B] >>> .bsdata range is [0x1FF, 0x398] ld.lld: error: section .bsdata load address range overlaps with .entrytext >>> .bsdata range is [0x1FF, 0x398] >>> .entrytext range is [0x26C, 0x2D3] Add .text.* to the .text output section to fix this, and also prevent any future surprises if the compiler decides to create other such sections. [1] https://reviews.llvm.org/D75225 Signed-off-by: Arvind Sankar <nivedita@alum.mit.edu> Signed-off-by: Kees Cook <keescook@chromium.org> Signed-off-by: Ingo Molnar <mingo@kernel.org> Tested-by: Nick Desaulniers <ndesaulniers@google.com> Tested-by: Sedat Dilek <sedat.dilek@gmail.com> Reviewed-by: Kees Cook <keescook@chromium.org> Reviewed-by: Ard Biesheuvel <ardb@kernel.org> Reviewed-by: Fangrui Song <maskray@google.com> Link: https://lore.kernel.org/r/20200731230820.1742553-5-keescook@chromium.org
66 lines
1.1 KiB
Text
66 lines
1.1 KiB
Text
/*
|
|
* setup.ld
|
|
*
|
|
* Linker script for the i386 setup code
|
|
*/
|
|
OUTPUT_FORMAT("elf32-i386")
|
|
OUTPUT_ARCH(i386)
|
|
ENTRY(_start)
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0;
|
|
.bstext : { *(.bstext) }
|
|
.bsdata : { *(.bsdata) }
|
|
|
|
. = 495;
|
|
.header : { *(.header) }
|
|
.entrytext : { *(.entrytext) }
|
|
.inittext : { *(.inittext) }
|
|
.initdata : { *(.initdata) }
|
|
__end_init = .;
|
|
|
|
.text : { *(.text .text.*) }
|
|
.text32 : { *(.text32) }
|
|
|
|
. = ALIGN(16);
|
|
.rodata : { *(.rodata*) }
|
|
|
|
.videocards : {
|
|
video_cards = .;
|
|
*(.videocards)
|
|
video_cards_end = .;
|
|
}
|
|
|
|
. = ALIGN(16);
|
|
.data : { *(.data*) }
|
|
|
|
.signature : {
|
|
setup_sig = .;
|
|
LONG(0x5a5aaa55)
|
|
}
|
|
|
|
|
|
. = ALIGN(16);
|
|
.bss :
|
|
{
|
|
__bss_start = .;
|
|
*(.bss)
|
|
__bss_end = .;
|
|
}
|
|
. = ALIGN(16);
|
|
_end = .;
|
|
|
|
/DISCARD/ : {
|
|
*(.note*)
|
|
}
|
|
|
|
/*
|
|
* The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
|
|
*/
|
|
. = ASSERT(_end <= 0x8000, "Setup too big!");
|
|
. = ASSERT(hdr == 0x1f1, "The setup header has the wrong offset!");
|
|
/* Necessary for the very-old-loader check to work... */
|
|
. = ASSERT(__end_init <= 5*512, "init sections too big!");
|
|
|
|
}
|