mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2024-09-12 21:57:43 +00:00
7f904d7e1f
Based on 1 normalized pattern(s): gplv2 extracted by the scancode license scanner the SPDX license identifier GPL-2.0-only has been chosen to replace the boilerplate/reference in 58 file(s). Signed-off-by: Thomas Gleixner <tglx@linutronix.de> Reviewed-by: Enrico Weigelt <info@metux.net> Reviewed-by: Allison Randal <allison@lohutok.net> Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Cc: linux-spdx@vger.kernel.org Link: https://lkml.kernel.org/r/20190604081207.556988620@linutronix.de Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
67 lines
1.3 KiB
Text
67 lines
1.3 KiB
Text
// SPDX-License-Identifier: GPL-2.0-only
|
|
///
|
|
/// Remove unneeded variable used to store return value.
|
|
///
|
|
// Confidence: Moderate
|
|
// Copyright: (C) 2012 Peter Senna Tschudin, INRIA/LIP6.
|
|
// URL: http://coccinelle.lip6.fr/
|
|
// Comments: Comments on code can be deleted if near code that is removed.
|
|
// "when strict" can be removed to get more hits, but adds false
|
|
// positives
|
|
// Options: --no-includes --include-headers
|
|
|
|
virtual patch
|
|
virtual report
|
|
virtual context
|
|
virtual org
|
|
|
|
@depends on patch@
|
|
type T;
|
|
constant C;
|
|
identifier ret;
|
|
@@
|
|
- T ret = C;
|
|
... when != ret
|
|
when strict
|
|
return
|
|
- ret
|
|
+ C
|
|
;
|
|
|
|
@depends on context@
|
|
type T;
|
|
constant C;
|
|
identifier ret;
|
|
@@
|
|
* T ret = C;
|
|
... when != ret
|
|
when strict
|
|
* return ret;
|
|
|
|
@r1 depends on report || org@
|
|
type T;
|
|
constant C;
|
|
identifier ret;
|
|
position p1, p2;
|
|
@@
|
|
T ret@p1 = C;
|
|
... when != ret
|
|
when strict
|
|
return ret@p2;
|
|
|
|
@script:python depends on report@
|
|
p1 << r1.p1;
|
|
p2 << r1.p2;
|
|
C << r1.C;
|
|
ret << r1.ret;
|
|
@@
|
|
coccilib.report.print_report(p1[0], "Unneeded variable: \"" + ret + "\". Return \"" + C + "\" on line " + p2[0].line)
|
|
|
|
@script:python depends on org@
|
|
p1 << r1.p1;
|
|
p2 << r1.p2;
|
|
C << r1.C;
|
|
ret << r1.ret;
|
|
@@
|
|
cocci.print_main("unneeded \"" + ret + "\" variable", p1)
|
|
cocci.print_sec("return " + C + " here", p2)
|