vbatts/grub
1
0
Fork 0
Code Issues Pull requests Releases Wiki Activity

2009-05-13 Javier Martín <lordhabbit@gmail.com>

Browse source 
* commands/i386/pc/drivemap.c: New file - implement drivemap
	command.
	* commands/i386/pc/drivemap_int13h.S: New file - int13 handler.
	* conf/i386-pc.rmk: Add drivemap.c and drivemap_int13h.S.
This commit is contained in:
proski 2009-05-14 01:23:49 +00:00
parent 6f6a8b2869
commit 4246b8a9e8
4 changed files with 526 additions and 1 deletions
Download patch file Download diff file Expand all files Collapse all files

66
commands/i386/pc/drivemap_int13h.S Normal file
View file

@ -0,0 +1,66 @@
/* drivemap_int13h.S - interrupt handler for the BIOS drive remapper */
/*
* GRUB -- GRand Unified Bootloader
* Copyright (C) 2008, 2009 Free Software Foundation, Inc.
*
* GRUB is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* GRUB is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with GRUB. If not, see <http://www.gnu.org/licenses/>.
*/
#include <grub/symbol.h>
#define INT13H_OFFSET(x) ((x) - grub_drivemap_handler)
.code16
/* Copy starts here. When deployed, this code must be segment-aligned. */
/* The replacement int13 handler. The code must be position independent.
Preserve all registers. */
FUNCTION(grub_drivemap_handler)
/* Map the drive number (always in DL). */
push %ax
push %bx
movw $INT13H_OFFSET(grub_drivemap_mapstart), %bx
more_remaining:
movw %cs:(%bx), %ax
cmpb %ah, %al
jz not_found /* DRV=DST => map end - drive not remapped, keep DL. */
cmpb %dl, %al
jz found /* Found - drive remapped, modify DL. */
inc %bx
inc %bx
jmp more_remaining /* Not found, but more remaining, loop. */
found:
movb %ah, %dl
not_found:
pop %bx
pop %ax
/* Upon arrival to this point the stack must be exactly like at entry.
This long jump will transfer the caller's stack to the old INT13
handler, thus making it return directly to the original caller. */
.byte 0xea
/* Far pointer to the old handler. Stored as a CS:IP in the style of real-mode
IVT entries (thus PI:SC in mem). */
VARIABLE(grub_drivemap_oldhandler)
.word 0x0, 0x0
/* This label MUST be at the end of the copied block, since the installer code
reserves additional space for mappings at runtime and copies them over it. */
.align 2
VARIABLE(grub_drivemap_mapstart)