/* startup.S - bootstrap GRUB itself */
/*
 *  GRUB  --  GRand Unified Bootloader
 *  Copyright (C) 2006,2007  Free Software Foundation, Inc.
 *
 *  GRUB is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  GRUB is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
 */

#include <config.h>
#include <grub/symbol.h>
#include <grub/boot.h>

        .file   "startup.S"
        .text
        .globl  start, _start
        .code64

start:
_start:
	jmp codestart

        /*
         *  Compatibility version number
         *
         *  These MUST be at byte offset 6 and 7 of the executable
         *  DO NOT MOVE !!!
         */
        . = EXT_C(start) + 0x6
        .byte   GRUB_BOOT_VERSION_MAJOR, GRUB_BOOT_VERSION_MINOR

        /*
         *  This is a special data area 8 bytes from the beginning.
         */

        . = EXT_C(start) + 0x8

VARIABLE(grub_prefix)
	/* to be filled by grub-mkimage */

        /*
         *  Leave some breathing room for the prefix.
         */

        . = EXT_C(start) + 0x50

codestart:

	movq	%rcx, EXT_C(grub_efi_image_handle)
	movq	%rdx, EXT_C(grub_efi_system_table)

	call	EXT_C(grub_main)
	ret

	.code32

FUNCTION(grub_linux_real_boot)
        /* Turn off PG bit in CR0 and set CR3 to zero.  */
        movl    %cr0, %eax
        andl    $0x7FFFFFFF, %eax
        movl    %eax, %cr0

        /* Setup EFER (Extended Feature Enable Register).  */
        movl    $0xc0000080, %ecx
        rdmsr

        /* Disable Long Mode.  */
        andl    $0xFFFFFEFF, %eax

        /* Make changes effective.  */
        wrmsr

        /* Disable PAE.  */
        xorl    %eax, %eax
        movl    %eax, %cr4

        jmp     *%ebx