63963d17d0
Drivemap fixes * commands/i386/pc/drivemap.c (grub_get_root_biosnumber_drivemap): new function (grub_get_root_biosnumber_saved): new variable (GRUB_MOD_INIT): register grub_get_root_biosnumber_drivemap (GRUB_MOD_FINI): unregister grub_get_root_biosnumber_drivemap * commands/i386/pc/drivemap_int13h.S (grub_drivemap_handler): restore %dx after the call if necessary * conf/common.rmk (pkglib_MODULES): remove boot.mod (boot_mod_SOURCES): remove (boot_mod_CFLAGS): remove (boot_mod_LDFLAGS): remove * conf/i386-coreboot.rmk (pkglib_MODULES): add boot.mod (boot_mod_SOURCES): new variable (boot_mod_CFLAGS): likewise (boot_mod_LDFLAGS): likewise * conf/i386-efi.rmk: likewise * conf/i386-ieee1275.rmk: likewise * conf/i386-pc.rmk: likewise * conf/powerpc-ieee1275.rmk: likewise * conf/sparc64-ieee1275.rmk: likewise * conf/x86_64-efi.rmk: likewise * include/grub/i386/pc/biosnum.h: new file * lib/i386/pc/biosnum.c: likewise * loader/i386/bsd.c (grub_bsd_get_device): use grub_get_root_biosnumber * loader/i386/multiboot.c (grub_multiboot_get_bootdev): likewise * loader/i386/pc/chainloader.c (grub_chainloader_cmd): likewise
109 lines
2.6 KiB
ArmAsm
109 lines
2.6 KiB
ArmAsm
/* drivemap_int13h.S - interrupt handler for the BIOS drive remapper */
|
|
/*
|
|
* GRUB -- GRand Unified Bootloader
|
|
* Copyright (C) 2008, 2009 Free Software Foundation, Inc.
|
|
*
|
|
* GRUB is free software: you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License as published by
|
|
* the Free Software Foundation, either version 3 of the License, or
|
|
* (at your option) any later version.
|
|
*
|
|
* GRUB is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with GRUB. If not, see <http://www.gnu.org/licenses/>.
|
|
*/
|
|
|
|
#include <grub/symbol.h>
|
|
|
|
#define INT13H_OFFSET(x) ((x) - EXT_C(grub_drivemap_handler))
|
|
|
|
.code16
|
|
|
|
/* Copy starts here. When deployed, this code must be segment-aligned. */
|
|
|
|
/* The replacement int13 handler. Preserve all registers. */
|
|
FUNCTION(grub_drivemap_handler)
|
|
/* Save %dx for future restore. */
|
|
push %dx
|
|
/* Push flags. Used to simulate interrupt with original flags. */
|
|
pushf
|
|
|
|
/* Map the drive number (always in DL). */
|
|
push %ax
|
|
push %bx
|
|
#ifdef APPLE_CC
|
|
grub_drivemap_mapstart_ofs = INT13H_OFFSET(EXT_C(grub_drivemap_mapstart))
|
|
movw $grub_drivemap_mapstart_ofs, %bx
|
|
#else
|
|
movw $INT13H_OFFSET(EXT_C(grub_drivemap_mapstart)), %bx
|
|
#endif
|
|
|
|
more_remaining:
|
|
movw %cs:(%bx), %ax
|
|
cmpb %ah, %al
|
|
jz not_found /* DRV=DST => map end - drive not remapped, keep DL. */
|
|
inc %bx
|
|
inc %bx
|
|
cmpb %dl, %al
|
|
jnz more_remaining /* Not found, but more remaining, loop. */
|
|
movb %ah, %dl /* Found - drive remapped, modify DL. */
|
|
|
|
not_found:
|
|
pop %bx
|
|
pop %ax
|
|
|
|
cmpb $0x8, %ah
|
|
jz norestore
|
|
cmpb $0x15, %ah
|
|
jz norestore
|
|
|
|
/* Restore flags. */
|
|
popf
|
|
pushf
|
|
|
|
lcall *%cs:INT13H_OFFSET (EXT_C (grub_drivemap_oldhandler))
|
|
|
|
push %bp
|
|
mov %sp, %bp
|
|
|
|
tail:
|
|
|
|
pushf
|
|
pop %dx
|
|
mov %dx, 8(%bp)
|
|
|
|
pop %bp
|
|
|
|
/* Restore %dx. */
|
|
pop %dx
|
|
iret
|
|
|
|
norestore:
|
|
|
|
/* Restore flags. */
|
|
popf
|
|
pushf
|
|
|
|
lcall *%cs:INT13H_OFFSET (EXT_C (grub_drivemap_oldhandler))
|
|
|
|
push %bp
|
|
mov %sp, %bp
|
|
|
|
/* Save %dx. */
|
|
mov %dx, 2(%bp)
|
|
|
|
jmp tail
|
|
|
|
/* Far pointer to the old handler. Stored as a CS:IP in the style of real-mode
|
|
IVT entries (thus PI:SC in mem). */
|
|
VARIABLE(grub_drivemap_oldhandler)
|
|
.word 0x0, 0x0
|
|
|
|
/* This label MUST be at the end of the copied block, since the installer code
|
|
reserves additional space for mappings at runtime and copies them over it. */
|
|
.align 2
|
|
VARIABLE(grub_drivemap_mapstart)
|