766f7d0809
* grub-core/kern/i386/coreboot/init.c (grub_machine_init): Use _edata and _start. * grub-core/kern/i386/coreboot/startup.S: Move multiboot header after the small code. It moves it only by few bytes but simplifies the code. * grub-core/kern/i386/pc/init.c (grub_machine_init): Use _edata and _start. * grub-core/kern/i386/pc/startup.S: Use _edata and _start. (grub_kernel_image_size): Removed. * grub-core/kern/i386/qemu/startup.S: Use _edata and _start. (grub_kernel_image_size): Removed. [APPLE_CC]: Remove apple compiler support. i386-qemu port can't be compiled with Apple toolchain. * grub-core/kern/sparc64/ieee1275/crt0.S: Remove leftover fields. * include/grub/i386/pc/kernel.h (grub_kernel_image_size): Removed. * include/grub/i386/qemu/kernel.h (grub_kernel_image_size): Removed. (grub_total_module_size): Likewise. * include/grub/offsets.h (GRUB_KERNEL_I386_PC_KERNEL_IMAGE_SIZE): Removed. (GRUB_KERNEL_I386_PC_COMPRESSED_SIZE): Put it lower. (GRUB_KERNEL_I386_PC_INSTALL_DOS_PART): Likewise. (GRUB_KERNEL_I386_PC_INSTALL_BSD_PART): Likewise. (GRUB_KERNEL_I386_PC_REED_SOLOMON_REDUNDANCY): Likewise. (GRUB_KERNEL_I386_QEMU_KERNEL_IMAGE_SIZE): Removed. (GRUB_KERNEL_SPARC64_IEEE1275_KERNEL_IMAGE_SIZE): Likewise. (GRUB_KERNEL_SPARC64_IEEE1275_COMPRESSED_SIZE): Likewise. * include/grub/sparc64/ieee1275/kernel.h (grub_kernel_image_size): Removed. (grub_total_module_size): Removed. * util/grub-mkimage.c (image_target_desc): Remove image_size. (image_targets): Likewise. Set .compressed_size to no field on sparc. (generate_image): Remove kernel_image_size handling.
82 lines
2.2 KiB
ArmAsm
82 lines
2.2 KiB
ArmAsm
/* crt0.S - Startup code for the Sparc64. */
|
|
/*
|
|
* GRUB -- GRand Unified Bootloader
|
|
* Copyright (C) 2009 Free Software Foundation, Inc.
|
|
*
|
|
* GRUB is free software: you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License as published by
|
|
* the Free Software Foundation, either version 3 of the License, or
|
|
* (at your option) any later version.
|
|
*
|
|
* GRUB is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with GRUB. If not, see <http://www.gnu.org/licenses/>.
|
|
*/
|
|
#include <grub/symbol.h>
|
|
#include <grub/machine/kernel.h>
|
|
#include <grub/offsets.h>
|
|
|
|
.text
|
|
.align 4
|
|
.globl _start
|
|
_start:
|
|
ba codestart
|
|
mov %o4, %o0
|
|
|
|
. = EXT_C(_start) + GRUB_KERNEL_MACHINE_TOTAL_MODULE_SIZE
|
|
|
|
VARIABLE(grub_total_module_size)
|
|
.word 0
|
|
|
|
codestart:
|
|
/* Copy the modules past the end of the kernel image.
|
|
* They are currently sitting in the BSS.
|
|
*/
|
|
sethi %hi(__bss_start), %o2
|
|
or %o2, %lo(__bss_start), %o2
|
|
sethi %hi(_end), %o3
|
|
or %o3, %lo(_end), %o3
|
|
sethi %hi(grub_total_module_size), %o4
|
|
lduw [%o4 + %lo(grub_total_module_size)], %o4
|
|
|
|
add %o2, %o4, %o2
|
|
add %o3, %o4, %o3
|
|
|
|
/* Save ieee1275 stack for future use by booter. */
|
|
mov %o6, %o1
|
|
/* Our future stack. */
|
|
sethi %hi(GRUB_KERNEL_MACHINE_STACK_SIZE), %o5
|
|
or %o5, %lo(GRUB_KERNEL_MACHINE_STACK_SIZE), %o5
|
|
add %o3, %o5, %o6
|
|
and %o6, ~0xff, %o6
|
|
sub %o6, 2047, %o6
|
|
|
|
sub %o2, 4, %o2
|
|
sub %o3, 4, %o3
|
|
1: lduw [%o2], %o5
|
|
stw %o5, [%o3]
|
|
subcc %o4, 4, %o4
|
|
sub %o2, 4, %o2
|
|
bne,pt %icc, 1b
|
|
sub %o3, 4, %o3
|
|
|
|
/* Now it's safe to clear out the BSS. */
|
|
sethi %hi(__bss_start), %o2
|
|
or %o2, %lo(__bss_start), %o2
|
|
sethi %hi(_end), %o3
|
|
or %o3, %lo(_end), %o3
|
|
1: stx %g0, [%o2]
|
|
add %o2, 8, %o2
|
|
cmp %o2, %o3
|
|
blt,pt %xcc, 1b
|
|
nop
|
|
sethi %hi(grub_ieee1275_original_stack), %o2
|
|
stx %o1, [%o2 + %lo(grub_ieee1275_original_stack)]
|
|
sethi %hi(grub_ieee1275_entry_fn), %o2
|
|
call grub_main
|
|
stx %o0, [%o2 + %lo(grub_ieee1275_entry_fn)]
|
|
1: ba,a 1b
|