524a1e6a40
Clean up the code to support 64-bit addressing in disks and
files. This change is not enough for filesystems yet.
* util/i386/pc/grub-setup.c (struct boot_blocklist): Change the
type of "start" to grub_uint64_t.
(setup): Change the types of KERNEL_SECTOR and FIRST_SECTOR to
grub_disk_addr_t * and grub_disk_addr_t. Fix the format string in
save_first_sector and save_blocklists. Use grub_le_to_cpu64 to
convert addresses.
* util/i386/pc/biosdisk.c (open_device): Change the type of SECTOR
to grub_disk_addr_t.
* partmap/gpt.c (gpt_partition_map_iterate): Fix the format
string.
* partmap/pc.c (pc_partition_map_iterate): Likewise.
* partmap/amiga.c (amiga_partition_map_iterate): Cast RDSK.MAGIC
to char *.
* normal/script.c (grub_script_parse): Remove unused MEMFREE.
* normal/parser.y (YYLTYPE_IS_TRIVIAL): New macro.
* normal/lexer.c (grub_script_yyerror): Specify unused to LEX.
* loader/i386/pc/multiboot.c (grub_multiboot_load_elf64): Cast -1
to grub_off_t, to detect an error from grub_file_seek.
(grub_multiboot_load_elf32): Likewise.
* kern/misc.c (grub_strtoul): Use grub_strtoull. Return the
maximum unsigned long value when an overflow is detected.
(grub_strtoull): New function.
(grub_divmod64): Likewise.
(grub_lltoa): use grub_divmod64.
* kern/fs.c (struct grub_fs_block): Change the type of "offset" to
grub_disk_addr_t.
(grub_fs_blocklist_open): Increase P if P is not NULL to advance
the pointer to next character. Use grub_strtoull instead of
grub_strtoul.
(grub_fs_blocklist_read): Change the types of SECTOR, OFFSET and
SIZE to grub_disk_addr_t, grub_off_t and grub_size_t,
respectively.
* kern/file.c (grub_file_read): Prevent an oveflow of LEN, as the
return value is signed.
(grub_file_seek): Change the type of OLD to grub_off_t. Do not
test if OFFSET is less than zero, as OFFSET is unsigned now.
* kern/disk.c (struct grub_disk_cache): Change the type of
"sector" to grub_disk_addr_t.
(grub_disk_cache_get_index): Change the type of SECTOR to
grub_disk_addr_t. Calculate the hash with SECTOR casted to
unsigned after shifting.
(grub_disk_cache_invalidate): Change the type of SECTOR to
grub_disk_addr_t.
(grub_disk_cache_unlock): Likewise.
(grub_disk_cache_store): Likewise.
(grub_disk_check_range): Change the types of SECTOR, OFFSET, SIZE,
START and LEN to grub_disk_addr_t *, grub_off_t *, grub_size_t,
grub_disk_addr_t and grub_uint64_t, respectively.
(grub_disk_read): Use an unsigned variable REAL_OFFSET for the
body, as the value of OFFSET is tweaked by
grub_disk_check_range. Change the types of START_SECTOR, LEN and
POS to grub_disk_addr_t, grub_size_t and grub_size_t,
respectively.
(grub_disk_write): Use an unsigned variable REAL_OFFSET for the
body, as the value of OFFSET is tweaked by
grub_disk_check_range. Change the types of LEN and N to
grub_size_t.
* io/gzio.c (struct grub_gzio): Change the types of "data_offset"
and "saved_offset" to grub_off_t.
(test_header): Cast BUF to char *.
(get_byte): Cast GZIO->DATA_OFFSET to grub_off_t. Cast GZIO->INBUF
to char *.
(grub_gzio_read): Change the types of OFFSET and SIZE to
grub_off_t and grub_size_t, respectively.
* include/grub/i386/pc/boot.h (GRUB_BOOT_MACHINE_FORCE_LBA):
Removed.
(GRUB_BOOT_MACHINE_BOOT_DRIVE): Changed to 0x4c.
(GRUB_BOOT_MACHINE_KERNEL_ADDRESS): Changed to 0x40.
(GRUB_BOOT_MACHINE_KERNEL_SEGMENT): Changed to 0x42.
(GRUB_BOOT_MACHINE_DRIVE_CHECK): Changed to 0x4e.
(GRUB_BOOT_MACHINE_LIST_SIZE): Increased to 12.
* include/grub/types.h (grub_off_t): Unconditionally set to
grub_uint64_t.
(grub_disk_addr_t): Changed to grub_uint64_t.
* include/grub/partition.h (struct grub_partition): Change the
types of "start", "len" and "offset" to grub_disk_addr_t,
grub_uint64_t and grub_disk_addr_t, respectively.
(grub_partition_get_start): Return grub_disk_addr_t.
(grub_partition_get_len): Return grub_uint64_t.
* include/grub/misc.h (grub_strtoull): New prototype.
(grub_divmod64): Likewise.
* include/grub/fshelp.h (grub_fshelp_read_file): Change the types
of SECTOR, LEN and FILESIZE to grub_disk_addr_t, grub_size_t and
grub_off_t, respectively.
All callers and references changed.
* include/grub/fs.h (struct grub_fs): Change the type of LEN to
grub_size_t in "read".
All callers and references changed.
* include/grub/file.h (struct grub_file): Change the types of
"offset" and "size" to grub_off_t and grub_off_t,
respectively. Change the type of SECTOR to grub_disk_addr_t in
"read_hook".
(grub_file_read): Change the type of LEN to grub_size_t.
(grub_file_seek): Return grub_off_t. Change the type of OFFSET to
grub_off_t.
(grub_file_size): Return grub_off_t.
(grub_file_tell): Likewise.
All callers and references changed.
* include/grub/disk.h (struct grub_disk_dev): Change the types of
SECTOR and SIZE to grub_disk_addr_t and grub_size_t in "read" and
"write".
(struct grub_disk): Change the type of "total_sectors" to
grub_uint64_t. Change the type of SECTOR to grub_disk_addr_t in
"read_hook".
(grub_disk_read): Change the types of SECTOR, OFFSET and SIZE to
grub_disk_addr_t, grub_off_t and grub_size_t, respectively.
(grub_disk_write): Likewise.
All callers and references changed.
* fs/iso9660.c (grub_iso9660_susp_iterate): Cast parameters to
char * for grub_strncmp to silence gcc.
(grub_iso9660_mount): Likewise.
(grub_iso9660_mount): Likewise.
(grub_iso9660_read_symlink): Likewise. Also, remove the nonsense
return statement.
(grub_iso9660_iterate_dir): Likewise.
(grub_iso9660_label): Cast DATA->VOLDESC.VOLNAME to char *.
* fs/hfs.c (grub_hfs_read_file): Change the types of SECTOR and
LEN to grub_disk_addr_t and grub_size_t, respectively.
* fs/hfsplus.c (grub_hfsplus_read_file): Likewise.
* fs/jfs.c (grub_jfs_read_file): Likewise.
* fs/minix.c (grub_jfs_read_file): Likewise.
* fs/sfs.c (grub_jfs_read_file): Likewise.
* fs/ufs.c (grub_jfs_read_file): Likewise.
* fs/xfs.c (grub_jfs_read_file): Likewise.
* fs/fat.c (grub_fat_read_data): Change the types of SECTOR, LEN
and SIZE to grub_disk_addr_t, grub_size_t and grub_size_t,
respectively.
* fs/ext2.c (grub_ext2_read_block): When an error happens, set
BLKNR to -1 instead of returning GRUB_ERRNO.
(grub_ext2_read_file): Change the types of SECTOR and
LEN to grub_disk_addr_t and grub_size_t, respectively.
* fs/affs.c (grub_affs_read_file): Change the types of SECTOR and
LEN to grub_disk_addr_t and grub_size_t, respectively.
* font/manager.c (grub_font_get_glyph): Cast BITMAP to char * for
grub_file_read.
* disk/ieee1275/ofdisk.c (grub_ofdisk_read): Fix the format
string. Do not cast SECTOR explicitly.
* disk/i386/pc/biosdisk.c (grub_biosdisk_open): Change the type of
TOTAL_SECTORS to grub_uint64_t. Do not mask DRP->TOTAL_SECTORS.
(grub_biosdisk_rw): Change the types of SECTOR and SIZE to
grub_disk_addr_t and grub_size_t, respectively. If the sector is
over 2TB and LBA mode is not supported, raise an error.
(get_safe_sectors): New function.
(grub_biosdisk_read): Use get_safe_sectors.
(grub_biosdisk_write): Likewise.
* disk/efi/efidisk.c (grub_efidisk_read): Fix the format string.
(grub_efidisk_write): Likewise.
* disk/loopback.c (delete_loopback): Cosmetic changes.
(grub_cmd_loopback): Likewise. Also, test NEWDEV->FILENAME
correctly.
(grub_loopback_open): Likewise.
(grub_loopback_read): Likewise. Also, change the type of POS to
grub_off_t, and fix the usage of grub_memset.
* commands/i386/pc/play.c: Include grub/machine/time.h.
* commands/ls.c (grub_ls_list_files): Use "llu" instead of "d" to
print FILE->SIZE.
* commands/configfile.c: Include grub/env.h.
* commands/cmp.c (grub_cmd_cmp): Do not use ERR, but use
GRUB_ERRNO directly instead. Change the type of POS to
grub_off_t. Follow the coding standard.
* commands/blocklist.c: Include grub/partition.h.
(grub_cmd_blocklist): Return an error if the underlying device is
not a disk. Take the starting sector of a partition into account,
if a partition is used.
* boot/i386/pc/diskboot.S (bootloop): Adapted to the new offset of
a length field.
(lba_mode): Support 64-bit addresses.
(chs_mode): Likewise.
(copy_buffer): Adapted to the new offsets of a length field and a
segment field.
(blocklist_default_start): Allocate 64-bit space.
* boot/i386/pc/boot.S (force_lba): Removed.
(boot_drive): Moved to under KERNEL_SECTOR.
(kernel_sector): Moved to under KENREL_SEGMENT. Allocate 64-bit
space.
(real_start): Set %si earlier. Remove code for FORCE_LBA, since it
is useless.
(lba_mode): Refactored to support a 64-bit address. More size
optimization.
(setup_sectors): Likewise.
487 lines
9.7 KiB
ArmAsm
487 lines
9.7 KiB
ArmAsm
/* -*-Asm-*- */
|
|
/*
|
|
* GRUB -- GRand Unified Bootloader
|
|
* Copyright (C) 1999,2000,2001,2002,2005,2006 Free Software Foundation, Inc.
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License as published by
|
|
* the Free Software Foundation; either version 2 of the License, or
|
|
* (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
|
|
*/
|
|
|
|
#include <grub/boot.h>
|
|
#include <grub/machine/boot.h>
|
|
|
|
/*
|
|
* defines for the code go here
|
|
*/
|
|
|
|
/* Absolute addresses
|
|
This makes the assembler generate the address without support
|
|
from the linker. (ELF can't relocate 16-bit addresses!) */
|
|
#define ABS(x) (x-_start+0x7c00)
|
|
|
|
/* Print message string */
|
|
#define MSG(x) movw $ABS(x), %si; call message
|
|
|
|
/* XXX: binutils-2.9.1.0.x doesn't produce a short opcode for this. */
|
|
#define MOV_MEM_TO_AL(x) .byte 0xa0; .word x
|
|
|
|
.file "boot.S"
|
|
|
|
.text
|
|
|
|
/* Tell GAS to generate 16-bit instructions so that this code works
|
|
in real mode. */
|
|
.code16
|
|
|
|
.globl _start; _start:
|
|
/*
|
|
* _start is loaded at 0x7c00 and is jumped to with CS:IP 0:0x7c00
|
|
*/
|
|
|
|
/*
|
|
* Beginning of the sector is compatible with the FAT/HPFS BIOS
|
|
* parameter block.
|
|
*/
|
|
|
|
jmp after_BPB
|
|
nop /* do I care about this ??? */
|
|
|
|
/*
|
|
* This space is for the BIOS parameter block!!!! Don't change
|
|
* the first jump, nor start the code anywhere but right after
|
|
* this area.
|
|
*/
|
|
|
|
. = _start + 4
|
|
|
|
/* scratch space */
|
|
mode:
|
|
.byte 0
|
|
disk_address_packet:
|
|
sectors:
|
|
.long 0
|
|
heads:
|
|
.long 0
|
|
cylinders:
|
|
.word 0
|
|
sector_start:
|
|
.byte 0
|
|
head_start:
|
|
.byte 0
|
|
cylinder_start:
|
|
.word 0
|
|
/* more space... */
|
|
|
|
. = _start + GRUB_BOOT_MACHINE_BPB_END
|
|
|
|
/*
|
|
* End of BIOS parameter block.
|
|
*/
|
|
|
|
boot_version:
|
|
.byte GRUB_BOOT_VERSION_MAJOR, GRUB_BOOT_VERSION_MINOR
|
|
kernel_address:
|
|
.word GRUB_BOOT_MACHINE_KERNEL_ADDR
|
|
kernel_segment:
|
|
.word GRUB_BOOT_MACHINE_KERNEL_SEG
|
|
kernel_sector:
|
|
.long 1, 0
|
|
boot_drive:
|
|
.byte 0xff /* the disk to load kernel from */
|
|
/* 0xff means use the boot drive */
|
|
|
|
after_BPB:
|
|
|
|
/* general setup */
|
|
cli /* we're not safe here! */
|
|
|
|
/*
|
|
* This is a workaround for buggy BIOSes which don't pass boot
|
|
* drive correctly. If GRUB is installed into a HDD, check if
|
|
* DL is masked correctly. If not, assume that the BIOS passed
|
|
* a bogus value and set DL to 0x80, since this is the only
|
|
* possible boot drive. If GRUB is installed into a floppy,
|
|
* this does nothing (only jump).
|
|
*/
|
|
boot_drive_check:
|
|
jmp 1f
|
|
testb $0x80, %dl
|
|
jnz 1f
|
|
movb $0x80, %dl
|
|
1:
|
|
|
|
/*
|
|
* ljmp to the next instruction because some bogus BIOSes
|
|
* jump to 07C0:0000 instead of 0000:7C00.
|
|
*/
|
|
ljmp $0, $ABS(real_start)
|
|
|
|
real_start:
|
|
|
|
/* set up %ds and %ss as offset from 0 */
|
|
xorw %ax, %ax
|
|
movw %ax, %ds
|
|
movw %ax, %ss
|
|
|
|
/* set up the REAL stack */
|
|
movw $GRUB_BOOT_MACHINE_STACK_SEG, %sp
|
|
|
|
sti /* we're safe again */
|
|
|
|
/*
|
|
* Check if we have a forced disk reference here
|
|
*/
|
|
MOV_MEM_TO_AL(ABS(boot_drive)) /* movb ABS(boot_drive), %al */
|
|
cmpb $0xff, %al
|
|
je 1f
|
|
movb %al, %dl
|
|
1:
|
|
/* save drive reference first thing! */
|
|
pushw %dx
|
|
|
|
/* print a notification message on the screen */
|
|
MSG(notification_string)
|
|
|
|
/* set %si to the disk address packet */
|
|
movw $ABS(disk_address_packet), %si
|
|
|
|
/* do not probe LBA if the drive is a floppy */
|
|
testb $GRUB_BOOT_MACHINE_BIOS_HD_FLAG, %dl
|
|
jz chs_mode
|
|
|
|
/* check if LBA is supported */
|
|
movb $0x41, %ah
|
|
movw $0x55aa, %bx
|
|
int $0x13
|
|
|
|
/*
|
|
* %dl may have been clobbered by INT 13, AH=41H.
|
|
* This happens, for example, with AST BIOS 1.04.
|
|
*/
|
|
popw %dx
|
|
pushw %dx
|
|
|
|
/* use CHS if fails */
|
|
jc chs_mode
|
|
cmpw $0xaa55, %bx
|
|
jne chs_mode
|
|
|
|
andw $1, %cx
|
|
jz chs_mode
|
|
|
|
lba_mode:
|
|
xorw %ax, %ax
|
|
movw %ax, 4(%si)
|
|
|
|
incw %ax
|
|
/* set the mode to non-zero */
|
|
movb %al, -1(%si)
|
|
|
|
/* the blocks */
|
|
movw %ax, 2(%si)
|
|
|
|
/* the size and the reserved byte */
|
|
movw $0x0010, (%si)
|
|
|
|
/* the absolute address */
|
|
movl ABS(kernel_sector), %ebx
|
|
movl %ebx, 8(%si)
|
|
movl ABS(kernel_sector + 4), %ebx
|
|
movl %ebx, 12(%si)
|
|
|
|
/* the segment of buffer address */
|
|
movw $GRUB_BOOT_MACHINE_BUFFER_SEG, 6(%si)
|
|
|
|
/*
|
|
* BIOS call "INT 0x13 Function 0x42" to read sectors from disk into memory
|
|
* Call with %ah = 0x42
|
|
* %dl = drive number
|
|
* %ds:%si = segment:offset of disk address packet
|
|
* Return:
|
|
* %al = 0x0 on success; err code on failure
|
|
*/
|
|
|
|
movb $0x42, %ah
|
|
int $0x13
|
|
|
|
/* LBA read is not supported, so fallback to CHS. */
|
|
jc chs_mode
|
|
|
|
movw $GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
|
|
jmp copy_buffer
|
|
|
|
chs_mode:
|
|
/*
|
|
* Determine the hard disk geometry from the BIOS!
|
|
* We do this first, so that LS-120 IDE floppies work correctly.
|
|
*/
|
|
movb $8, %ah
|
|
int $0x13
|
|
jnc final_init
|
|
|
|
/*
|
|
* The call failed, so maybe use the floppy probe instead.
|
|
*/
|
|
testb $GRUB_BOOT_MACHINE_BIOS_HD_FLAG, %dl
|
|
jz floppy_probe
|
|
|
|
/* Nope, we definitely have a hard disk, and we're screwed. */
|
|
jmp hd_probe_error
|
|
|
|
final_init:
|
|
/* set the mode to zero */
|
|
movzbl %dh, %eax
|
|
movb %ah, -1(%si)
|
|
|
|
/* save number of heads */
|
|
incw %ax
|
|
movl %eax, 4(%si)
|
|
|
|
movzbw %cl, %dx
|
|
shlw $2, %dx
|
|
movb %ch, %al
|
|
movb %dh, %ah
|
|
|
|
/* save number of cylinders */
|
|
incw %ax
|
|
movw %ax, 8(%si)
|
|
|
|
movzbw %dl, %ax
|
|
shrb $2, %al
|
|
|
|
/* save number of sectors */
|
|
movl %eax, (%si)
|
|
|
|
setup_sectors:
|
|
/* load logical sector start (top half) */
|
|
movl ABS(kernel_sector + 4), %eax
|
|
orl %eax, %eax
|
|
jnz geometry_error
|
|
|
|
/* load logical sector start (bottom half) */
|
|
movl ABS(kernel_sector), %eax
|
|
|
|
/* zero %edx */
|
|
xorl %edx, %edx
|
|
|
|
/* divide by number of sectors */
|
|
divl (%si)
|
|
|
|
/* save sector start */
|
|
movb %dl, %cl
|
|
|
|
xorw %dx, %dx /* zero %edx */
|
|
divl 4(%si) /* divide by number of heads */
|
|
|
|
/* do we need too many cylinders? */
|
|
cmpw 8(%si), %ax
|
|
jge geometry_error
|
|
|
|
/* normalize sector start (1-based) */
|
|
incb %cl
|
|
|
|
/* low bits of cylinder start */
|
|
movb %al, %ch
|
|
|
|
/* high bits of cylinder start */
|
|
xorb %al, %al
|
|
shrw $2, %ax
|
|
orb %al, %cl
|
|
|
|
/* save head start */
|
|
movb %dl, %al
|
|
|
|
/* restore %dl */
|
|
popw %dx
|
|
|
|
/* head start */
|
|
movb %al, %dh
|
|
|
|
/*
|
|
* BIOS call "INT 0x13 Function 0x2" to read sectors from disk into memory
|
|
* Call with %ah = 0x2
|
|
* %al = number of sectors
|
|
* %ch = cylinder
|
|
* %cl = sector (bits 6-7 are high bits of "cylinder")
|
|
* %dh = head
|
|
* %dl = drive (0x80 for hard disk, 0x0 for floppy disk)
|
|
* %es:%bx = segment:offset of buffer
|
|
* Return:
|
|
* %al = 0x0 on success; err code on failure
|
|
*/
|
|
|
|
movw $GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
|
|
movw %bx, %es /* load %es segment with disk buffer */
|
|
|
|
xorw %bx, %bx /* %bx = 0, put it at 0 in the segment */
|
|
movw $0x0201, %ax /* function 2 */
|
|
int $0x13
|
|
|
|
jc read_error
|
|
|
|
movw %es, %bx
|
|
|
|
copy_buffer:
|
|
movw ABS(kernel_segment), %es
|
|
|
|
/*
|
|
* We need to save %cx and %si because the startup code in
|
|
* kernel uses them without initializing them.
|
|
*/
|
|
pusha
|
|
pushw %ds
|
|
|
|
movw $0x100, %cx
|
|
movw %bx, %ds
|
|
xorw %si, %si
|
|
xorw %di, %di
|
|
|
|
cld
|
|
|
|
rep
|
|
movsw
|
|
|
|
popw %ds
|
|
popa
|
|
|
|
/* boot kernel */
|
|
jmp *(kernel_address)
|
|
|
|
/* END OF MAIN LOOP */
|
|
|
|
/*
|
|
* BIOS Geometry translation error (past the end of the disk geometry!).
|
|
*/
|
|
geometry_error:
|
|
MSG(geometry_error_string)
|
|
jmp general_error
|
|
|
|
/*
|
|
* Disk probe failure.
|
|
*/
|
|
hd_probe_error:
|
|
MSG(hd_probe_error_string)
|
|
jmp general_error
|
|
|
|
/*
|
|
* Read error on the disk.
|
|
*/
|
|
read_error:
|
|
MSG(read_error_string)
|
|
|
|
general_error:
|
|
MSG(general_error_string)
|
|
|
|
/* go here when you need to stop the machine hard after an error condition */
|
|
/* tell the BIOS a boot failure, which may result in no effect */
|
|
int $0x18
|
|
stop: jmp stop
|
|
|
|
notification_string: .string "GRUB "
|
|
geometry_error_string: .string "Geom"
|
|
hd_probe_error_string: .string "Hard Disk"
|
|
read_error_string: .string "Read"
|
|
general_error_string: .string " Error"
|
|
|
|
/*
|
|
* message: write the string pointed to by %si
|
|
*
|
|
* WARNING: trashes %si, %ax, and %bx
|
|
*/
|
|
|
|
/*
|
|
* Use BIOS "int 10H Function 0Eh" to write character in teletype mode
|
|
* %ah = 0xe %al = character
|
|
* %bh = page %bl = foreground color (graphics modes)
|
|
*/
|
|
1:
|
|
movw $0x0001, %bx
|
|
movb $0xe, %ah
|
|
int $0x10 /* display a byte */
|
|
message:
|
|
lodsb
|
|
cmpb $0, %al
|
|
jne 1b /* if not end of string, jmp to display */
|
|
ret
|
|
|
|
/*
|
|
* Windows NT breaks compatibility by embedding a magic
|
|
* number here.
|
|
*/
|
|
|
|
. = _start + GRUB_BOOT_MACHINE_WINDOWS_NT_MAGIC
|
|
nt_magic:
|
|
.long 0
|
|
.word 0
|
|
|
|
/*
|
|
* This is where an MBR would go if on a hard disk. The code
|
|
* here isn't even referenced unless we're on a floppy. Kinda
|
|
* sneaky, huh?
|
|
*/
|
|
|
|
part_start:
|
|
. = _start + GRUB_BOOT_MACHINE_PART_START
|
|
|
|
probe_values:
|
|
.byte 36, 18, 15, 9, 0
|
|
|
|
floppy_probe:
|
|
/*
|
|
* Perform floppy probe.
|
|
*/
|
|
|
|
movw $ABS(probe_values-1), %si
|
|
|
|
probe_loop:
|
|
/* reset floppy controller INT 13h AH=0 */
|
|
xorw %ax, %ax
|
|
int $0x13
|
|
|
|
incw %si
|
|
movb (%si), %cl
|
|
|
|
/* if number of sectors is 0, display error and die */
|
|
cmpb $0, %cl
|
|
jne 1f
|
|
|
|
/*
|
|
* Floppy disk probe failure.
|
|
*/
|
|
MSG(fd_probe_error_string)
|
|
jmp general_error
|
|
|
|
fd_probe_error_string: .string "Floppy"
|
|
|
|
1:
|
|
/* perform read */
|
|
movw $GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
|
|
movw $0x201, %ax
|
|
movb $0, %ch
|
|
movb $0, %dh
|
|
int $0x13
|
|
|
|
/* if error, jump to "probe_loop" */
|
|
jc probe_loop
|
|
|
|
/* %cl is already the correct value! */
|
|
movb $1, %dh
|
|
movb $79, %ch
|
|
|
|
jmp final_init
|
|
|
|
. = _start + GRUB_BOOT_MACHINE_PART_END
|
|
|
|
/* the last 2 bytes in the sector 0 contain the signature */
|
|
.word GRUB_BOOT_MACHINE_SIGNATURE
|